[arch-commits] Commit in gnome-online-miners/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 19, 2020 @ 08:37:37
  Author: felixonmars
Revision: 386401

archrelease: copy trunk to staging-x86_64

Added:
  gnome-online-miners/repos/staging-x86_64/
  gnome-online-miners/repos/staging-x86_64/PKGBUILD
    (from rev 386400, gnome-online-miners/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: gnome-online-miners/repos/staging-x86_64/PKGBUILD (from rev 386400, gnome-online-miners/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-19 08:37:37 UTC (rev 386401)
@@ -0,0 +1,39 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=gnome-online-miners
+pkgver=3.34.0
+pkgrel=2
+pkgdesc="Crawls through your online content"
+arch=(x86_64)
+url="https://wiki.gnome.org/Projects/GnomeOnlineMiners"
+license=(GPL)
+depends=(libgdata gnome-online-accounts grilo libzapojit tracker gfbgraph dleyna-server)
+makedepends=(git autoconf-archive python)
+_commit=f9aca437b511ca95e1ea6dab68c099aa9e9ae119  # tags/3.34.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-online-miners.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+  
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --libexecdir=/usr/lib --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}
+
+# vim:set ts=2 sw=2 et: