[arch-commits] Commit in gtk-vnc/repos (staging-x86_64 staging-x86_64/PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Tue May 19 08:41:22 UTC 2020
Date: Tuesday, May 19, 2020 @ 08:41:21
Author: felixonmars
Revision: 386426
archrelease: copy trunk to staging-x86_64
Added:
gtk-vnc/repos/staging-x86_64/
gtk-vnc/repos/staging-x86_64/PKGBUILD
(from rev 386425, gtk-vnc/trunk/PKGBUILD)
----------+
PKGBUILD | 46 ++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
Copied: gtk-vnc/repos/staging-x86_64/PKGBUILD (from rev 386425, gtk-vnc/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD (rev 0)
+++ staging-x86_64/PKGBUILD 2020-05-19 08:41:21 UTC (rev 386426)
@@ -0,0 +1,46 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Allan McRae <mcrae_allan at hotmail.com>
+# Contributor: lp76 <l.peduto at gmail.com>
+
+pkgname=gtk-vnc
+pkgver=1.0.0
+pkgrel=2
+pkgdesc="A VNC viewer widget for GTK+"
+url="https://wiki.gnome.org/Projects/gtk-vnc"
+arch=(x86_64)
+license=(LGPL)
+depends=(libgcrypt gtk3 gnutls libpulse)
+makedepends=(vala gobject-introspection git perl-text-csv meson)
+_commit=99ce0ff670f1ba2947a2f36ec853cc7fbf015678 # tags/v1.0.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gtk-vnc.git#commit=$_commit"
+ git+https://gitlab.com/keycodemap/keycodemapdb.git)
+sha256sums=('SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd $pkgname
+ git describe --tags | sed 's/^v//;s/-/+/g'
+}
+
+prepare() {
+ cd $pkgname
+
+ git submodule init
+ git config --local submodule.src/keycodemapdb.url "$srcdir/keycodemapdb"
+ git submodule update
+}
+
+build() {
+ arch-meson $pkgname build
+ ninja -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+ install -Dt "$pkgdir/usr/bin" build/examples/gvncviewer
+}
More information about the arch-commits
mailing list