[arch-commits] Commit in conky/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Tue May 19 08:46:43 UTC 2020


    Date: Tuesday, May 19, 2020 @ 08:46:43
  Author: felixonmars
Revision: 386469

archrelease: copy trunk to staging-x86_64

Added:
  conky/repos/staging-x86_64/
  conky/repos/staging-x86_64/PKGBUILD
    (from rev 386468, conky/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: conky/repos/staging-x86_64/PKGBUILD (from rev 386468, conky/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-19 08:46:43 UTC (rev 386469)
@@ -0,0 +1,49 @@
+# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: James Rayner <james at archlinux.org>
+# Contributor: Partha Chowdhury <kira.laucas at gmail.com>
+
+pkgname=conky
+pkgver=1.11.5
+pkgrel=3
+pkgdesc='Lightweight system monitor for X'
+url='https://github.com/brndnmtthws/conky'
+license=('BSD' 'GPL')
+arch=('x86_64')
+makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
+depends=('glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft'
+         'imlib2' 'libxml2' 'libpulse' 'libxnvctrl')
+source=("https://github.com/brndnmtthws/conky/archive/v${pkgver}.tar.gz")
+sha256sums=('4cefdd92219a90934c28297e4ac7448a3f69d6aeec5d48c5763b23f6b214ef13')
+options=('!strip' 'debug')
+
+build() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+
+	cmake \
+		-D CMAKE_BUILD_TYPE=Release \
+		-D MAINTAINER_MODE=ON \
+		-D BUILD_DOCS=ON \
+		-D BUILD_WLAN=ON \
+		-D BUILD_XDBE=ON \
+		-D BUILD_XSHAPE=ON \
+		-D BUILD_IMLIB2=ON \
+		-D BUILD_CURL=ON \
+		-D BUILD_RSS=ON \
+		-D BUILD_NVIDIA=ON \
+		-D BUILD_WEATHER_METAR=ON \
+		-D BUILD_PULSEAUDIO=ON \
+		-D BUILD_JOURNAL=ON \
+		-D CMAKE_INSTALL_PREFIX=/usr \
+		.
+
+	make
+}
+
+package() {
+	cd "${srcdir}/${pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+	install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	install -Dm644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
+	install -Dm644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
+}


More information about the arch-commits mailing list