[arch-commits] Commit in dleyna-server/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Felix Yan]

    Date: Tuesday, May 19, 2020 @ 08:48:27
  Author: felixonmars
Revision: 386481

archrelease: copy trunk to staging-x86_64

Added:
  dleyna-server/repos/staging-x86_64/
  dleyna-server/repos/staging-x86_64/PKGBUILD
    (from rev 386480, dleyna-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: dleyna-server/repos/staging-x86_64/PKGBUILD (from rev 386480, dleyna-server/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-19 08:48:27 UTC (rev 386481)
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+
+pkgname=dleyna-server
+pkgver=0.6.0+2+geb895ae
+pkgrel=2
+pkgdesc="Library to discover, browse and manipulate Digital Media Servers"
+arch=(x86_64)
+url="http://01.org/dleyna"
+license=(LGPL2.1)
+depends=(dleyna-connector-dbus gupnp-av gupnp-dlna libsoup)
+makedepends=(git)
+_commit=eb895ae82715e9889a948ffa810c0f828b4f4c76  # master
+source=("git+https://github.com/01org/dleyna-server#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+build() {
+  cd $pkgname
+  CFLAGS+=" -Wno-deprecated-declarations"
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --disable-static --libexecdir=/usr/lib
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+check() {
+  cd $pkgname
+  make check
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+}