[arch-commits] Commit in colord/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Tue May 19 08:48:15 UTC 2020


    Date: Tuesday, May 19, 2020 @ 08:48:15
  Author: felixonmars
Revision: 386480

archrelease: copy trunk to staging-x86_64

Added:
  colord/repos/staging-x86_64/
  colord/repos/staging-x86_64/PKGBUILD
    (from rev 386477, colord/trunk/PKGBUILD)

----------+
 PKGBUILD |   66 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

Copied: colord/repos/staging-x86_64/PKGBUILD (from rev 386477, colord/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-05-19 08:48:15 UTC (rev 386480)
@@ -0,0 +1,66 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgbase=colord
+pkgname=(colord colord-sane)
+pkgver=1.4.4+9+g1ce26da
+pkgrel=2
+pkgdesc="System daemon for managing color devices"
+url="https://www.freedesktop.org/software/colord"
+arch=(x86_64)
+license=(GPL2)
+depends=(lcms2 libgusb polkit sqlite dconf dbus libgudev shared-mime-info systemd-libs udev)
+makedepends=(gobject-introspection vala sane bash-completion argyllcms git meson gtk-doc systemd
+             docbook-xsl)
+options=(!emptydirs)
+_commit=1ce26daa5bc786869dac6ba309b698480ef31bac  # master
+source=("git+https://github.com/hughsie/colord#commit=$_commit")
+sha256sums=('SKIP')
+validpgpkeys=('163EB50119225DB3DF8F49EA17ACBA8DFA970E17')  # Richard Hughes
+
+pkgver() {
+  cd colord
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd colord
+}
+
+build() {
+  arch-meson colord build \
+    -D libcolordcompat=true \
+    -D sane=true \
+    -D vapi=true \
+    -D print_profiles=true \
+    -D daemon_user=colord
+  ninja -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_colord() {
+  optdepends=('argyllcms: color profiling'
+              'colord-sane: SANE support')
+  replaces=(shared-color-profiles)
+
+  DESTDIR="$pkgdir" meson install -C build
+
+  echo 'u colord - "Color management daemon" /var/lib/colord' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/colord.conf"
+
+### Split colord-sane
+  mkdir -p colord-sane/usr/lib/colord-plugins
+  mv {"$pkgdir",colord-sane}/usr/lib/colord-sane
+  mv {"$pkgdir",colord-sane}/usr/lib/colord-plugins/libcolord_sensor_sane.so
+}
+
+package_colord-sane() {
+  pkgdesc+=" (SANE support)"
+  depends=("colord=$pkgver-$pkgrel" sane)
+  mv colord-sane/* "$pkgdir"
+}
+
+# vim:set sw=2 et:


More information about the arch-commits mailing list