[arch-commits] Commit in efivar/trunk (PKGBUILD)

[David Runge]

    Date: Tuesday, May 19, 2020 @ 21:03:00
  Author: dvzrv
Revision: 386961

upgpkg: efivar 37-4: Rebuilding for reproducibility.

Updating pkgdesc to reflect upstream.
Updating url to current rhboot team on github.
Adding libefivar.so and libefiboot.so to provides. Adding glibc to depends.
Removing unrequired popt from depends. Removing redundant options array.
Adding PGP key of Peter Jones (B00B48BC731AA8840FED9FB0EED266B70F4FEF10) and checking tag against it.
Removing -Werror from gcc.specs and all cherry-picked commits (as they were failing due to -Werror).
Removing unnecessary parameters to make and simplifying the make calls.
Minor cleanups and installing docs.
Updating maintainer info.

Modified:
  efivar/trunk/PKGBUILD

----------+
 PKGBUILD |   85 ++++++++++++++++++++++++++-----------------------------------
 1 file changed, 37 insertions(+), 48 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2020-05-19 20:54:44 UTC (rev 386960)
+++ PKGBUILD	2020-05-19 21:03:00 UTC (rev 386961)
@@ -1,62 +1,51 @@
-# Maintainer : Tobias Powalowski <tpowa at archlinux.org>
-# Contributor : Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Tobias Powalowski <tpowa at archlinux.org>
+# Contributor: Keshav Amburay <(the ddoott ridikulus ddoott rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
 
-pkgname="efivar"
-pkgdesc="Tools and library to manipulate EFI variables"
+pkgname=efivar
+pkgdesc="Tools and libraries to work with EFI variables"
 pkgver=37
-pkgrel=3
+pkgrel=4
 arch=('x86_64')
-url="https://github.com/rhinstaller/efivar"
+url="https://github.com/rhboot/efivar"
 license=('LGPL2.1')
 makedepends=('git')
-depends=('popt')
-conflicts=('libefivar')
-provides=("libefivar=${pkgver}")
-options=('strip' 'zipman' 'docs')
-source=("efivar::git+https://github.com/rhinstaller/efivar.git#tag=${pkgver}")
+depends=('glibc')
+provides=('libefiboot.so' 'libefivar.so')
+source=("git+https://github.com/rhinstaller/efivar.git#tag=${pkgver}?signed")
+sha512sums=('SKIP')
+validpgpkeys=('B00B48BC731AA8840FED9FB0EED266B70F4FEF10') # Peter Jones <pjones at redhat.com>
 
-#source=("efivar::git+https://github.com/rhinstaller/efivar.git#commit=8740389dded9202167007508670daefd33a7985f")
-sha1sums=('SKIP')
-
-pkgver() {
-	cd "${srcdir}/efivar/"
-	echo "$(git describe --tags)" | sed -e 's|efivar-||g' -e 's|-|\.|g'
-}
-
 prepare() {
-	cd "${srcdir}/efivar/"
-
-	git clean -x -d -f
-	echo
-
-	# fix build with recent gcc
-	git cherry-pick -n \
-		b98ba8921010d03f46704a476c69861515deb1ca \
-		c3c553db85ff10890209d0fe48fb4856ad68e4e0 \
-		0dad6d78a7fb5f6c5fb4a1d646040539db6cf865 \
-		fdb803402fb32fa6d020bac57a40c7efe4aabb7d \
-		4e04afc2df9bbc26e5ab524b53a6f4f1e61d7c9e
-
-	sed 's|-O0|-Os|g' -i "${srcdir}/efivar/Make.defaults" || true
-	sed 's|-rpath,$(TOPDIR)/src|-rpath,$(libdir)|g' -i "${srcdir}/efivar/src/test/Makefile" || true
+  mv -v "${pkgname}" "${pkgname}-${pkgver}"
+  cd "${pkgname}-${pkgver}"
+  # -Werror, not even once
+  sed -e 's/-Werror//g' -i gcc.specs
+  # remove insecure rpath in efivar-tester
+  sed 's|-rpath,$(TOPDIR)/src|-rpath,$(libdir)|g' -i src/test/Makefile
 }
 
 build() {
-	cd "${srcdir}/efivar/"
-	CFLAGS="${CFLAGS} -flto"
-
-	make libdir="/usr/lib/" bindir="/usr/bin/" mandir="/usr/share/man/" includedir="/usr/include/" V=1 -j1
-	cd "${srcdir}/efivar/src/test"
-	make libdir="/usr/lib/" bindir="/usr/bin/" mandir="/usr/share/man/" includedir="/usr/include/" V=1 -j1
-	echo
+  cd "${pkgname}-${pkgver}"
+  make libdir="/usr/lib/" \
+       bindir="/usr/bin/" \
+       mandir="/usr/share/man/" \
+       includedir="/usr/include/"
+  # build efivar-tester
+  make libdir="/usr/lib/" \
+       bindir="/usr/bin/" \
+       mandir="/usr/share/man/" \
+       includedir="/usr/include/" \
+       -C src/test
 }
 
 package() {
-	cd "${srcdir}/efivar/"
-
-	make -j1 V=1 DESTDIR="${pkgdir}/" libdir="/usr/lib/" bindir="/usr/bin/" mandir="/usr/share/man/" includedir="/usr/include/" install
-	echo
-
-	install -d "${pkgdir}/usr/bin"
-	install -D -m0755 "${srcdir}/efivar/src/test/tester" "${pkgdir}/usr/bin/efivar-tester"
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}/" \
+       libdir="/usr/lib/" \
+       bindir="/usr/bin/" \
+       mandir="/usr/share/man/" \
+       includedir="/usr/include/" install -j1 V=1
+  install -vDm 755 "src/test/tester" "${pkgdir}/usr/bin/efivar-tester"
+  install -vDm 644 {README.md,TODO} -t "${pkgdir}/usr/share/doc/${pkgname}"
 }