[arch-commits] Commit in haskell-yaml/repos (2 files)

Felix Yan felixonmars at archlinux.org
Tue May 19 22:14:58 UTC 2020


    Date: Tuesday, May 19, 2020 @ 22:14:58
  Author: felixonmars
Revision: 630275

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yaml/repos/community-staging-x86_64/
  haskell-yaml/repos/community-staging-x86_64/PKGBUILD
    (from rev 630274, haskell-yaml/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-yaml/repos/community-staging-x86_64/PKGBUILD (from rev 630274, haskell-yaml/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-05-19 22:14:58 UTC (rev 630275)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yaml
+pkgname=haskell-yaml
+pkgver=0.11.4.0
+pkgrel=4
+pkgdesc="Support for parsing and rendering YAML documents."
+url="https://github.com/snoyberg/yaml/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-conduit' 'haskell-libyaml'
+         'haskell-vector' 'haskell-resourcet' 'haskell-scientific' 'haskell-unordered-containers')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-mockery' 'haskell-base-compat'
+             'haskell-raw-strings-qq' 'haskell-temporary')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('bed04ff53a7ebce6fc117fc1986e9ff95cae6f2de0e050b0f8607abc42d057e34a31e0cbda23def6a0caf15eb20b946af8869daf7e6df9c5797ce241057bb5fc')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}


More information about the arch-commits mailing list