[arch-commits] Commit in pandoc/repos (2 files)

[Felix Yan]

    Date: Sunday, May 24, 2020 @ 16:53:27
  Author: felixonmars
Revision: 632989

archrelease: copy trunk to community-staging-x86_64

Added:
  pandoc/repos/community-staging-x86_64/
  pandoc/repos/community-staging-x86_64/PKGBUILD
    (from rev 632988, pandoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   75 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 75 insertions(+)

Copied: pandoc/repos/community-staging-x86_64/PKGBUILD (from rev 632988, pandoc/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-05-24 16:53:27 UTC (rev 632989)
@@ -0,0 +1,75 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=pandoc
+pkgver=2.9.2.1
+pkgrel=45
+pkgdesc='Conversion between markup formats'
+url='https://pandoc.org'
+license=('GPL')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-http' 'haskell-juicypixels' 'haskell-sha' 'haskell-aeson'
+         'haskell-aeson-pretty' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-blaze-html' 'haskell-blaze-markup'
+         'haskell-case-insensitive' 'haskell-cmark-gfm' 'haskell-data-default' 'haskell-doclayout'
+         'haskell-doctemplates' 'haskell-emojis' 'haskell-glob'
+         'haskell-haddock-library' 'haskell-ipynb' 'haskell-jira-wiki-markup' 'haskell-skylighting'
+         'haskell-skylighting-core' 'haskell-hslua' 'haskell-hslua-module-system'
+         'haskell-hslua-module-text' 'haskell-http-client' 'haskell-syb' 'haskell-hsyaml'
+         'haskell-http-client-tls' 'haskell-http-types' 'haskell-safe' 'haskell-split'
+         'haskell-texmath' 'haskell-network' 'haskell-pandoc-types' 'haskell-random'
+         'haskell-scientific' 'haskell-tagsoup' 'haskell-temporary' 'haskell-text-conversions'
+         'haskell-network-uri' 'haskell-unicode-transforms' 'haskell-unordered-containers'
+         'haskell-zip-archive' 'haskell-vector' 'haskell-xml' 'haskell-zlib')
+optdepends=('pandoc-citeproc: for citation rendering with pandoc-citeproc filter'
+            'pandoc-crossref: for numbering figures, equations, tables and cross-references to them with pandoc-crossref filter'
+            'texlive-core: for pdf output')
+conflicts=('haskell-pandoc')
+replaces=('haskell-pandoc')
+makedepends=('ghc' 'haskell-diff' 'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-lua'
+             'haskell-tasty-quickcheck' 'haskell-tasty-golden' 'haskell-quickcheck'
+             'haskell-executable-path')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz"
+        pandoc-revert-noprelude.patch::https://github.com/jgm/pandoc/commit/a9ef15bbd574bf09827c2c25ef1cd3efaf288f7c.patch
+        pandoc-skylighting-0.8.4.patch::https://github.com/jgm/pandoc/commit/46179d5b3e84b5c709e09924cbda524230ebd3fe.patch)
+sha512sums=('35ac491a7e0a2f6d8fe0f2c2ffe265748b13920904e974f88c92b3f82edb2f1c03e28ebef1bc344ead13d566117a5e50707a68edc49f95159157f974210b23b2'
+            'ca91b56003c02cd10cc9a073f63eac6e3d4371ebec80bb85500ea67e8aa0ac8938fb5487651ad72e6f964b9d5266c1578e649323e3390037fb87b443850eb4e1'
+            '3c057b1bb41cf2346e4fb63c50d3edb745eb598ef5d69c63bc0de0dcfa8e55fce0e4d19d5ce4872ca5fede10ee0f3621fb350d7e162fe63a8d0e1dea8b796e5b')
+
+prepare() {
+    cd "${srcdir}/$pkgname-${pkgver}"
+    patch -p1 -i ../pandoc-revert-noprelude.patch
+    patch -p1 -i ../pandoc-skylighting-0.8.4.patch || :
+    sed -i 's/< 1.1/< 1.2/;s/< *2.14/<3/;s/< *1.3/<2/' $pkgname.cabal
+
+    # TODO: find a better solution
+    sed -i "s|let env' = dynlibEnv ++ |let env' = dynlibEnv ++ [(\"LD_LIBRARY_PATH\", \"$PWD/dist/build\")] ++ |" test/Tests/Command.hs
+}
+
+build() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-trypandoc -f-embed_data_files -f-static
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd "${srcdir}/${pkgname}-${pkgver}"
+    LC_CTYPE=en_US.UTF-8 runhaskell Setup test || warning "Tests failed"
+}
+
+package() {
+    cd "${srcdir}/${pkgbase}-${pkgver}"
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    rm "${pkgdir}/usr/share/doc/${pkgname}/COPYING.md"
+    install -Dm644 man/pandoc.1 "${pkgdir}"/usr/share/man/man1/pandoc.1
+}