[arch-commits] Commit in spice-vdagent/trunk (PKGBUILD)

[Balló György]

    Date: Thursday, May 28, 2020 @ 09:36:30
  Author: bgyorgy
Revision: 636211

upgpkg: spice-vdagent 0.20.0+6+g8adf50d-1: Update to git master to fix shutdown problems (FS#65870)

Modified:
  spice-vdagent/trunk/PKGBUILD

----------+
 PKGBUILD |   46 +++++++++++++++++++++++++++++-----------------
 1 file changed, 29 insertions(+), 17 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2020-05-28 09:26:36 UTC (rev 636210)
+++ PKGBUILD	2020-05-28 09:36:30 UTC (rev 636211)
@@ -2,7 +2,7 @@
 # Contributor: mutantmonkey <aur at mutantmonkey.in>
 
 pkgname=spice-vdagent
-pkgver=0.20.0
+pkgver=0.20.0+6+g8adf50d
 pkgrel=1
 pkgdesc="Spice agent for Linux guests"
 arch=('x86_64')
@@ -9,29 +9,41 @@
 url="https://www.spice-space.org/"
 license=('GPL')
 depends=('alsa-lib' 'dbus' 'glib2' 'gtk3' 'libdrm' 'libpciaccess' 'libxfixes' 'libxinerama' 'libxrandr' 'systemd')
-makedepends=('spice-protocol')
+makedepends=('spice-protocol' 'git')
+checkdepends=('procps-ng')
 backup=('etc/conf.d/spice-vdagentd')
-source=("https://www.spice-space.org/download/releases/$pkgname-$pkgver.tar.bz2")
-sha256sums=('2e6b7222675ee19ea38c52165abe4d836c2ac5d5bf902d4dfca13da1ec143359')
+_commit=8adf50de9ae6714e7a994aba7f6efa9f9528471e  # master
+source=("git+https://gitlab.freedesktop.org/spice/linux/vd_agent.git#commit=$_commit")
+sha256sums=('SKIP')
 
+pkgver() {
+  cd vd_agent
+  git describe --tags | sed 's/^spice-vdagent-//;s/-/+/g'
+}
+
 prepare() {
-	cd $pkgname-$pkgver
-	sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|
-	        s|/usr/sbin/spice-vdagentd|/usr/bin/spice-vdagentd|' data/spice-vdagentd.service
-	sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|' data/spice-vdagentd.1.in
+  cd vd_agent
+  sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|
+          s|/usr/sbin/spice-vdagentd|/usr/bin/spice-vdagentd|' data/spice-vdagentd.service
+  sed -i 's|/etc/sysconfig/spice-vdagentd|/etc/conf.d/spice-vdagentd|' data/spice-vdagentd.1.in
+  NOCONFIGURE=1 ./autogen.sh
 }
 
 build() {
-	cd $pkgname-$pkgver
-	./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin \
-	            --with-session-info=systemd --with-init-script=systemd
-	make
+  cd vd_agent
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --sbindir=/usr/bin \
+              --with-session-info=systemd --with-init-script=systemd
+  make
 }
 
+check() {
+  make -C vd_agent check
+}
+
 package() {
-	cd $pkgname-$pkgver
-	make DESTDIR="$pkgdir" install
-	rm -r "$pkgdir/var"
-	install -dm755 "$pkgdir/etc/conf.d/"
-	echo 'SPICE_VDAGENTD_EXTRA_ARGS=""' > "$pkgdir/etc/conf.d/spice-vdagentd"
+  cd vd_agent
+  make DESTDIR="$pkgdir" install
+  rm -r "$pkgdir/var"
+  install -dm755 "$pkgdir/etc/conf.d/"
+  echo 'SPICE_VDAGENTD_EXTRA_ARGS=""' > "$pkgdir/etc/conf.d/spice-vdagentd"
 }