[arch-commits] Commit in haskell-snap-core/repos (2 files)

[Felix Yan]

    Date: Thursday, May 28, 2020 @ 18:24:32
  Author: felixonmars
Revision: 636627

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-snap-core/repos/community-staging-x86_64/
  haskell-snap-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 636626, haskell-snap-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-snap-core/repos/community-staging-x86_64/PKGBUILD (from rev 636626, haskell-snap-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-05-28 18:24:32 UTC (rev 636627)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=snap-core
+pkgname=haskell-snap-core
+pkgver=1.0.4.1
+pkgrel=90
+pkgdesc="A Haskell Web Framework (core interfaces and types)"
+url="https://github.com/JustusAdam/snap-core"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-old-locale' 'haskell-hunit' 'haskell-attoparsec'
+         'haskell-case-insensitive' 'haskell-lifted-base' 'haskell-io-streams' 'haskell-hashable'
+         'haskell-monad-control' 'haskell-random' 'haskell-readable' 'haskell-regex-posix'
+         'haskell-transformers-base' 'haskell-unix-compat' 'haskell-unordered-containers'
+         'haskell-vector' 'haskell-network' 'haskell-network-uri')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-parallel' 'haskell-test-framework'
+             'haskell-test-framework-hunit' 'haskell-test-framework-quickcheck2' 'haskell-zlib')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('0d4f6a4152627773714c1ec5c9508d19a2e69c8ef83acab3669b0732b840aa67dfce7893638fba7689e35c5b3530ea1fd8d681f6aad045ccb2219e5910e83e34')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/bytestring-builder/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}