[arch-commits] Commit in libgphoto2/repos/extra-x86_64 (PKGBUILD PKGBUILD)

Jan Steffens heftig at archlinux.org
Fri May 29 16:18:48 UTC 2020


    Date: Friday, May 29, 2020 @ 16:18:48
  Author: heftig
Revision: 387850

archrelease: copy trunk to extra-x86_64

Added:
  libgphoto2/repos/extra-x86_64/PKGBUILD
    (from rev 387843, libgphoto2/trunk/PKGBUILD)
Deleted:
  libgphoto2/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  122 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 61 insertions(+), 61 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2020-05-29 16:18:47 UTC (rev 387849)
+++ PKGBUILD	2020-05-29 16:18:48 UTC (rev 387850)
@@ -1,61 +0,0 @@
-# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
-# Maintainer: Jan de Groot <jgc at archlinux.org>
-# Contributor: Tom Gundersen <teg at jklm.no>
-# Contributor: Eduardo Romero <eduardo at archlinux.org>
-# Contributor: Damir Perisa <damir.perisa at bluewin.ch>
-
-pkgname=libgphoto2
-pkgver=2.5.24
-pkgrel=1
-pkgdesc="The core library of gphoto2, designed to allow access to digital camera by external programs."
-url="http://www.gphoto.org/"
-arch=(x86_64)
-license=(LGPL)
-depends=(libexif libjpeg gd libltdl libusb libxml2)
-makedepends=(autoconf-archive git)
-provides=(libgphoto2.so)
-_commit=63f8c5233e73aedbf47f4a65fc30f579307cb4da  # tags/libgphoto2-2_5_24-release
-source=("git+https://github.com/gphoto/libgphoto2#commit=$_commit")
-sha256sums=('SKIP')
-validpgpkeys=('7C4AFD61D8AAE7570796A5172209D6902F969C95') # Marcus Meissner
-
-pkgver() {
-  cd $pkgname
-  git describe --tags | sed 's/^libgphoto2-//;s/-release//;s/_/./g;s/-/+/g'
-}
-
-prepare() {
-  cd $pkgname
-  autoreconf -fvi
-}
-
-build() {
-  cd $pkgname
-  ./configure --prefix=/usr --disable-rpath
-  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
-  make
-}
-
-package() {
-  cd $pkgname
-  make DESTDIR="$pkgdir" install
-
-  # Remove unused udev helper
-  rm -r "$pkgdir/usr/lib/udev"
-
-  _genudev
-}
-
-_genudev() (
-  cd "$pkgdir/usr/lib/libgphoto2"
-
-  export LD_LIBRARY_PATH="$pkgdir/usr/lib${LD_LIBRARY_PATH:+:}$LD_LIBRARY_PATH"
-  export CAMLIBS="$PWD/$pkgver"
-
-  ./print-camera-list hwdb \
-    | install -Dm644 /dev/stdin "$pkgdir/usr/lib/udev/hwdb.d/20-gphoto.hwdb"
-  ./print-camera-list udev-rules version 201 \
-    | install -Dm644 /dev/stdin "$pkgdir/usr/lib/udev/rules.d/40-gphoto.rules"
-)
-
-# vim:set sw=2 et:

Copied: libgphoto2/repos/extra-x86_64/PKGBUILD (from rev 387843, libgphoto2/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2020-05-29 16:18:48 UTC (rev 387850)
@@ -0,0 +1,61 @@
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens at gmail.com>
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tom Gundersen <teg at jklm.no>
+# Contributor: Eduardo Romero <eduardo at archlinux.org>
+# Contributor: Damir Perisa <damir.perisa at bluewin.ch>
+
+pkgname=libgphoto2
+pkgver=2.5.25
+pkgrel=1
+pkgdesc="The core library of gphoto2, designed to allow access to digital camera by external programs."
+url="http://www.gphoto.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(libexif libjpeg gd libltdl libusb libxml2 curl)
+makedepends=(autoconf-archive git)
+provides=(libgphoto2.so)
+_commit=8fa3d32ffdab83e2ad98576a7e8b00243e700d82  # tags/libgphoto2-2_5_25-release
+source=("git+https://github.com/gphoto/libgphoto2#commit=$_commit")
+sha256sums=('SKIP')
+validpgpkeys=('7C4AFD61D8AAE7570796A5172209D6902F969C95') # Marcus Meissner
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^libgphoto2-//;s/-release//;s/^v//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  autoreconf -fvi
+}
+
+build() {
+  cd $pkgname
+  ./configure --prefix=/usr --disable-rpath
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/    if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/      func_append compile_command " -Wl,-O1,--as-needed"\n      func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
+  make
+}
+
+package() {
+  cd $pkgname
+  make DESTDIR="$pkgdir" install
+
+  # Remove unused udev helper
+  rm -r "$pkgdir/usr/lib/udev"
+
+  _genudev
+}
+
+_genudev() (
+  cd "$pkgdir/usr/lib/libgphoto2"
+
+  export LD_LIBRARY_PATH="$pkgdir/usr/lib${LD_LIBRARY_PATH:+:}$LD_LIBRARY_PATH"
+  export CAMLIBS="$PWD/$pkgver"
+
+  ./print-camera-list hwdb \
+    | install -Dm644 /dev/stdin "$pkgdir/usr/lib/udev/hwdb.d/20-gphoto.hwdb"
+  ./print-camera-list udev-rules version 201 \
+    | install -Dm644 /dev/stdin "$pkgdir/usr/lib/udev/rules.d/40-gphoto.rules"
+)
+
+# vim:set sw=2 et:


More information about the arch-commits mailing list