[arch-commits] Commit in (4 files)
Chih-Hsuan Yen
yan12125 at archlinux.org
Sat May 30 06:38:24 UTC 2020
Date: Saturday, May 30, 2020 @ 06:38:23
Author: yan12125
Revision: 637396
python-pypugjs: dependency of upcoming buildbot
Ref: https://github.com/buildbot/buildbot/pull/5298
Added:
python-pypugjs/
python-pypugjs/repos/
python-pypugjs/trunk/
python-pypugjs/trunk/PKGBUILD
----------+
PKGBUILD | 33 +++++++++++++++++++++++++++++++++
1 file changed, 33 insertions(+)
Added: python-pypugjs/trunk/PKGBUILD
===================================================================
--- python-pypugjs/trunk/PKGBUILD (rev 0)
+++ python-pypugjs/trunk/PKGBUILD 2020-05-30 06:38:23 UTC (rev 637396)
@@ -0,0 +1,33 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: zwindl on AUR
+
+pkgname=python-pypugjs
+pkgver=5.9.4
+pkgrel=1
+pkgdesc='PugJS syntax adapter for Django, Jinja2 and Mako templates'
+url='https://github.com/kakulukia/pypugjs'
+depends=(python python-six python-chardet)
+makedepends=(python-setuptools)
+checkdepends=(python-nose python-django python-jinja python-tornado python-mako)
+optdepends=(python-django python-jinja python-tornado python-mako)
+license=(MIT)
+arch=(any)
+source=("https://github.com/kakulukia/pypugjs/archive/v$pkgver/pypugjs-$pkgver.tar.gz")
+sha256sums=('7e3c660e8fcd2b060a8781f69c3e9325d1167cd78b63ff29c381311042ef5bc7')
+
+build() {
+ cd pypugjs-$pkgver
+ python setup.py build
+}
+
+check() {
+ cd pypugjs-$pkgver
+ # -w is needed here as test_cases.py looks into cases/
+ PYTHONPATH="$PWD" nosetests -v -w pypugjs/testsuite
+}
+
+package() {
+ cd pypugjs-$pkgver
+ python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+ install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}
More information about the arch-commits
mailing list