[arch-commits] Commit in nextcloud-client/repos (2 files)

[Chih-Hsuan Yen]

    Date: Sunday, November 1, 2020 @ 10:04:01
  Author: yan12125
Revision: 738811

archrelease: copy trunk to community-testing-x86_64

Added:
  nextcloud-client/repos/community-testing-x86_64/
  nextcloud-client/repos/community-testing-x86_64/PKGBUILD
    (from rev 738810, nextcloud-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   70 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 70 insertions(+)

Copied: nextcloud-client/repos/community-testing-x86_64/PKGBUILD (from rev 738810, nextcloud-client/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2020-11-01 10:04:01 UTC (rev 738811)
@@ -0,0 +1,70 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+# Contributor: Tyler Dence <tyzoid at archlinux32.org>
+# Contributor: Konstantin Shalygin <k0ste at k0ste.ru>
+
+pkgname=nextcloud-client
+# Upstream does not provide signed tarballs (yet)
+# https://github.com/nextcloud/desktop/issues/1510
+pkgver=3.0.3
+pkgrel=1
+pkgdesc='Nextcloud desktop client'
+arch=(x86_64)
+url='https://nextcloud.com/'
+license=(GPL)
+depends=(openssl sqlite qtkeychain qt5-svg qt5-webengine xdg-utils libcloudproviders
+         qt5-graphicaleffects qt5-quickcontrols2)
+makedepends=(doxygen extra-cmake-modules kio python-sphinx qt5-tools git cmocka)
+optdepends=(
+  'kio: integration with Dolphin'
+  'nemo-python: integration with Nemo'
+  'python-nautilus: integration with Nautilus'
+  'python-caja: integration with Caja'
+)
+source=("$pkgname::git+https://github.com/nextcloud/desktop.git?signed#tag=v$pkgver")
+validpgpkeys=(
+  A26B951528EA1BA1678C7AE5D406C75CEE1A36D6  # one of keys controlled by github.com/camilasan
+  42E775EAA3E47F9E0D5CDB0E00819E3BF4177B28  # controlled by github.com/misch7
+  17166A5275C5FA6F1A48FD78074BBBCB8DECC9E2  # https://github.com/er-vin.gpg
+)
+sha256sums=('SKIP')
+backup=('etc/Nextcloud/sync-exclude.lst')
+
+prepare() {
+  # tmpdir for check()
+  mkdir tmpdir
+
+  # Use system GNUInstallDirs.cmake so that we can benefit from
+  # https://gitlab.kitware.com/cmake/cmake/merge_requests/3735
+  rm -v $pkgname/cmake/modules/GNUInstallDirs.cmake
+}
+
+build() {
+  cd $pkgname
+
+  # bundled breakpad in libcrashreporter-qt submodule is too old and does not build with glibc >= 2.26
+  # Upstream fix: https://github.com/google/breakpad/commit/bddcc58860f522a0d4cbaa7e9d04058caee0db9d
+  cmake -B build -S . \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DNO_SHIBBOLETH=1 \
+    -DWITH_CRASHREPORTER=OFF \
+    -DUNIT_TESTING=ON
+
+  # TODO: fix installation of PDF and HTML documents
+  # WIP at https://github.com/yan12125/desktop/tree/doc-install-path
+  make -C build all doc-man
+}
+
+check() {
+  cd $pkgname/build
+
+  # Tests fail if $TMPDIR is too small; specify an alternative for machines
+  # with a small /tmp partition.
+  TMPDIR="$srcdir/tmpdir" make test
+}
+
+package() {
+  cd $pkgname/build
+
+  make DESTDIR="$pkgdir" install
+}