[arch-commits] Commit in haskell-retrie/repos (2 files)

[Felix Yan]

    Date: Monday, November 2, 2020 @ 17:28:35
  Author: felixonmars
Revision: 740002

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-retrie/repos/community-staging-x86_64/
  haskell-retrie/repos/community-staging-x86_64/PKGBUILD
    (from rev 740001, haskell-retrie/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-retrie/repos/community-staging-x86_64/PKGBUILD (from rev 740001, haskell-retrie/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-02 17:28:35 UTC (rev 740002)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=retrie
+pkgname=haskell-retrie
+pkgver=0.1.1.1
+pkgrel=10
+pkgdesc="A powerful, easy-to-use codemodding tool for Haskell."
+url="https://github.com/facebookincubator/retrie"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ansi-terminal' 'haskell-async' 'haskell-data-default'
+         'haskell-ghc-exactprint' 'haskell-src-exts' 'haskell-optparse-applicative'
+         'haskell-random-shuffle' 'haskell-syb' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-ghc-paths' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-temporary')
+checkdepends=('git' 'mercurial')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('f162028ecbfea991f8a22701637b3869c8bd306f48823316c92496e4ea66d7d0')
+
+prepare() {
+  uusi $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+  rm "$pkgdir"/usr/bin/demo
+}