[arch-commits] Commit in hedgewars/repos (2 files)

[Felix Yan]

    Date: Monday, November 2, 2020 @ 17:43:24
  Author: felixonmars
Revision: 740026

archrelease: copy trunk to community-staging-x86_64

Added:
  hedgewars/repos/community-staging-x86_64/
  hedgewars/repos/community-staging-x86_64/PKGBUILD
    (from rev 740025, hedgewars/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: hedgewars/repos/community-staging-x86_64/PKGBUILD (from rev 740025, hedgewars/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-02 17:43:24 UTC (rev 740026)
@@ -0,0 +1,58 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Tinxy <arch at tinx dot eu>
+
+pkgname=hedgewars
+pkgver=1.0.0
+pkgrel=115
+pkgdesc="Turn-based strategy artillery game similiar to Worms"
+arch=('x86_64')
+url="https://hedgewars.org"
+license=('GPL' 'custom')
+depends=('qt5-base' 'sdl2' 'sdl2_mixer' 'sdl2_image' 'sdl2_net' 'sdl2_ttf' 'lua51' 'ffmpeg' 'glut'
+         'physfs' 'ghc-libs' 'haskell-entropy' 'haskell-sha' 'haskell-random' 'haskell-regex-tdfa'
+         'haskell-sandi' 'haskell-hslogger' 'haskell-network2.8' 'haskell-utf8-string' 'haskell-vector')
+makedepends=('fpc' 'cmake' 'qt5-tools' 'ghc' 'haskell-bytestring-show'
+             'haskell-zlib' 'haskell-base-prelude' 'imagemagick' 'mesa')
+source=("https://www.hedgewars.org/download/releases/hedgewars-src-$pkgver.tar.bz2")
+sha512sums=('9aeb904550239040a878a0e7ae5006aa4d824124b61d813b9e6f6dfe1bd1c8f5fe395e0fd6e58d685ef1259abd4669e03b985be129c620be15f6e5ad82519ec2')
+
+prepare() {
+  cd hedgewars-src-$pkgver
+  sed -i 's|set(ghc_flags|set(ghc_flags -dynamic -package network-2.8.0.1 -hide-package network-bsd|' gameServer/CMakeLists.txt
+  sed -i '/#include <QSizePolicy>/a #include <QPainterPath>' QTfrontend/ui/page/pagegamestats.cpp
+
+  # https://bugs.freepascal.org/view.php?id=37286
+  sed -i 's/procedure ShiftWorld(Dir: LongInt); inline;/procedure ShiftWorld(Dir: LongInt);/' hedgewars/uWorld.pas
+}
+
+build() {
+  cd hedgewars-src-$pkgver
+  cmake \
+    -DCMAKE_BUILD_TYPE="Release" \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DDATA_INSTALL_DIR=/usr/share/hedgewars \
+    -DNOSERVER=0 \
+    .
+  make
+
+  # resize icon
+  for _size in 16 32 48 64 128 256; do
+    convert +set date:create +set date:modify misc/hedgewars.png -resize ${_size}x${_size} hedgewars_${_size}.png
+  done
+}
+
+package() {
+  cd hedgewars-src-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -D -m644 Fonts_LICENSE.txt "$pkgdir"/usr/share/licenses/${pkgname}/Fonts_LICENSE.txt
+
+  # install icons
+  install -D -m644 misc/hedgewars.png "$pkgdir"/usr/share/icons/hicolor/512x512/apps/hedgewars.png
+  for _size in 16 32 48 64 128 256; do
+    install -D -m644 hedgewars_${_size}.png "$pkgdir"/usr/share/icons/hicolor/${_size}x${_size}/apps/hedgewars.png
+  done
+  rm -rf "$pkgdir"/usr/share/pixmaps
+
+  install -D -m644 share/hedgewars/Data/misc/hedgewars.desktop "$pkgdir"/usr/share/applications/hedgewars.desktop
+}