[arch-commits] Commit in haskell-servant/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 3, 2020 @ 05:54:35
  Author: felixonmars
Revision: 740280

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant/repos/community-staging-x86_64/
  haskell-servant/repos/community-staging-x86_64/PKGBUILD
    (from rev 740279, haskell-servant/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-servant/repos/community-staging-x86_64/PKGBUILD (from rev 740279, haskell-servant/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-03 05:54:35 UTC (rev 740280)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant
+pkgname=haskell-servant
+pkgver=0.18
+pkgrel=21
+pkgdesc="A family of combinators for defining webservices APIs"
+url="http://haskell-servant.readthedocs.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-attoparsec'
+         'haskell-bifunctors' 'haskell-case-insensitive' 'haskell-http-api-data'
+         'haskell-http-media' 'haskell-http-types' 'haskell-mmorph' 'haskell-network-uri'
+         'haskell-quickcheck' 'haskell-tagged' 'haskell-singleton-bool'
+         'haskell-string-conversions' 'haskell-vault')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ca88a25c745033be79c5b540873a0a128a722cac37d3c8cbe3c54d5b8ecc80f49589817f1dac4ab34bea677d156ffe9d0a2a641c11b2621f09fc0b6b54b9cd03')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i 's/< *0.4.2/<1/' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}