[arch-commits] Commit in haskell-conduit/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 3, 2020 @ 18:54:33
  Author: felixonmars
Revision: 741236

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-conduit/repos/community-staging-x86_64/
  haskell-conduit/repos/community-staging-x86_64/PKGBUILD
    (from rev 741235, haskell-conduit/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-conduit/repos/community-staging-x86_64/PKGBUILD (from rev 741235, haskell-conduit/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-03 18:54:33 UTC (rev 741236)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=conduit
+pkgname=haskell-conduit
+pkgver=1.3.3
+pkgrel=8
+pkgdesc="Streaming data processing library."
+url="https://github.com/snoyberg/conduit"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-mono-traversable' 'haskell-primitive'
+         'haskell-resourcet' 'haskell-unliftio-core' 'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck' 'haskell-safe' 'haskell-silently'
+             'haskell-split' 'haskell-unliftio')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('f3fc200dd59e44e77a2b16985ad8c5c6a056a2ef2e47b277c5527068c41ff2ee3af95964176689415308277d5d8d688ce7f9cae8d0da1888aa075b4df11074e3')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}