[arch-commits] Commit in haskell-lsp/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 4, 2020 @ 19:53:17
  Author: felixonmars
Revision: 742583

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lsp/repos/community-staging-x86_64/
  haskell-lsp/repos/community-staging-x86_64/PKGBUILD
    (from rev 742582, haskell-lsp/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-lsp/repos/community-staging-x86_64/PKGBUILD (from rev 742582, haskell-lsp/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-04 19:53:17 UTC (rev 742583)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=haskell-lsp
+pkgname=haskell-lsp
+pkgver=0.23.0.0
+pkgrel=19
+pkgdesc="Haskell library for the Microsoft Language Server Protocol"
+url="https://github.com/alanz/haskell-lsp"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-async' 'haskell-attoparsec' 'haskell-data-default'
+         'haskell-hashable' 'haskell-lsp-types' 'haskell-hslogger' 'haskell-lens'
+         'haskell-network-uri' 'haskell-rope-utf16-splay' 'haskell-sorted-list'
+         'haskell-temporary' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-hspec' 'haskell-hspec-discover'
+             'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('12b62e833f33bee80f586ee65e01b4927da8267a652929f13a6268fe18728981a5b1675f880eb14409dc23ecff252b71d184e1a567d7781ddb3dc8d1fd7b910c')
+
+build() {
+  cd $_hkgname-$pkgver    
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}