[arch-commits] Commit in haskell-tasty-lua/repos (2 files)

[Felix Yan]

    Date: Friday, November 6, 2020 @ 18:18:36
  Author: felixonmars
Revision: 744429

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tasty-lua/repos/community-staging-x86_64/
  haskell-tasty-lua/repos/community-staging-x86_64/PKGBUILD
    (from rev 744428, haskell-tasty-lua/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-tasty-lua/repos/community-staging-x86_64/PKGBUILD (from rev 744428, haskell-tasty-lua/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-06 18:18:36 UTC (rev 744429)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tasty-lua
+pkgname=haskell-tasty-lua
+pkgver=0.2.3.1
+pkgrel=10
+pkgdesc="Write tests in Lua, integrate into tasty."
+url="https://github.com/hslua/tasty-lua"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-file-embed' 'haskell-hslua' 'haskell-tasty')
+makedepends=('ghc' 'haskell-tasty-hunit')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('7c97f001ee2659ec48a8810505fc820607be9969151fe082157a33a308617b68be83a792b7ff1da3d492d14490fdc1b71a7d9bda2643be760a78f46fb5e98ad7')
+
+build() {
+    cd $_hkgname-$pkgver    
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}