[arch-commits] Commit in haskell-monad-logger/repos (2 files)

[Felix Yan]

    Date: Friday, November 6, 2020 @ 18:46:29
  Author: felixonmars
Revision: 744493

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-monad-logger/repos/community-staging-x86_64/
  haskell-monad-logger/repos/community-staging-x86_64/PKGBUILD
    (from rev 744492, haskell-monad-logger/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-monad-logger/repos/community-staging-x86_64/PKGBUILD (from rev 744492, haskell-monad-logger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-06 18:46:29 UTC (rev 744493)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=monad-logger
+pkgname=haskell-monad-logger
+pkgver=0.3.35
+pkgrel=35
+pkgdesc="A class of monads which can log messages."
+url="https://github.com/kazu-yamamoto/logger"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-conduit' 'haskell-conduit-extra'
+         'haskell-fast-logger' 'haskell-lifted-base' 'haskell-monad-control' 'haskell-monad-loops'
+         'haskell-resourcet' 'haskell-stm-chans'
+         'haskell-transformers-base' 'haskell-transformers-compat' 'haskell-unliftio-core')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('97eaf0860c39cfc7a12aac187874426c774a9476ea291f3ca74c725d89cd0b3602a6c0ae210c928c96d0444f7649fa16d296d6e5ca1b99375832997215d8d244')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -ftemplate_haskell
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}