[arch-commits] Commit in haskell-tz/repos (2 files)

[Felix Yan]

    Date: Friday, November 6, 2020 @ 23:41:05
  Author: felixonmars
Revision: 744755

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tz/repos/community-staging-x86_64/
  haskell-tz/repos/community-staging-x86_64/PKGBUILD
    (from rev 744754, haskell-tz/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-tz/repos/community-staging-x86_64/PKGBUILD (from rev 744754, haskell-tz/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-06 23:41:05 UTC (rev 744755)
@@ -0,0 +1,54 @@
+# Maintainer: Jelle van der Waa <jelle at archlinux.org>
+
+_hkgname=tz
+pkgname=haskell-tz
+pkgver=0.1.3.3
+pkgrel=66
+pkgdesc='Efficient time zone handling'
+arch=(x86_64)
+url='https://hackage.haskell.org/package/tz'
+license=(BSD)
+depends=(ghc-libs haskell-vector haskell-data-default haskell-tzdata)
+checkdepends=(haskell-test-framework-th haskell-hunit haskell-quickcheck
+              haskell-test-framework-quickcheck2 haskell-test-framework-hunit)
+makedepends=(ghc uusi)
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('54dacfde056e5f860062e1dcf9fe9a384e8725bb195d404b4b9a24ff50faaa777ff077330e06f336d369a61a855c0e09e3475477e1b34030dbab6d7c661a2452')
+
+prepare() {
+  uusi $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+    
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --enable-tests \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}
+
+# vim: ts=2 sw=2 et: