[arch-commits] Commit in haskell-http-api-data/repos (2 files)

[Felix Yan]

    Date: Saturday, November 7, 2020 @ 11:17:26
  Author: felixonmars
Revision: 745703

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-api-data/repos/community-staging-x86_64/
  haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD
    (from rev 745702, haskell-http-api-data/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD (from rev 745702, haskell-http-api-data/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-07 11:17:26 UTC (rev 745703)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-api-data
+pkgname=haskell-http-api-data
+pkgver=0.4.2
+pkgrel=22
+pkgdesc="Converting to/from HTTP API data like URL pieces, headers and query parameters."
+url="https://github.com/fizruk/http-api-data"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-attoparsec-iso8601' 'haskell-base-compat'
+         'haskell-cookie' 'haskell-hashable' 'haskell-http-types' 'haskell-tagged'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-uuid-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('99cd347221900e30678d5ceaf9d156d06fc31a9e05bc66f0cf8c90156835f1883d369673098d2f6ca2b838de88c67e6659807e73a8539b1e4c351fcc15bb9e2a')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i -e '/nats/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-use-text-show
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}