[arch-commits] Commit in python-six/repos (staging-any staging-any/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Mon Nov 9 11:19:43 UTC 2020


    Date: Monday, November 9, 2020 @ 11:19:43
  Author: felixonmars
Revision: 399666

archrelease: copy trunk to staging-any

Added:
  python-six/repos/staging-any/
  python-six/repos/staging-any/PKGBUILD
    (from rev 399665, python-six/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: python-six/repos/staging-any/PKGBUILD (from rev 399665, python-six/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2020-11-09 11:19:43 UTC (rev 399666)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Jelle van der Waa <jelle at vdwaa.nl>
+# Contributer: Allan McRae <allan at archlinux.org>
+
+pkgbase=python-six
+pkgname=('python2-six' 'python-six')
+pkgver=1.15.0
+pkgrel=2
+pkgdesc="Python 2 and 3 compatibility utilities"
+arch=('any')
+url="https://pypi.python.org/pypi/six/"
+license=('MIT')
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest' 'python2-pytest' 'tk')
+source=("https://pypi.io/packages/source/s/six/six-$pkgver.tar.gz")
+sha512sums=('eb840ac17f433f1fc4af56de75cfbfe0b54e6a737bb23c453bf09a4a13d768d153e46064880dc763f4c5cc2785b78ea6d3d3b4a41fed181cb9064837e3f699a9')
+
+build() {
+  cp -a six-$pkgver{,-py2}
+}
+
+check() {
+  cd "$srcdir"/six-$pkgver
+  python -m pytest
+
+  cd "$srcdir"/six-$pkgver-py2
+  python2 -m pytest
+}
+
+package_python-six() {
+  depends=('python')
+
+  cd six-$pkgver
+  python setup.py install --root "$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-six() {
+  depends=('python2')
+
+  cd six-$pkgver-py2
+  python2 setup.py install --root "$pkgdir" --optimize=1
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}


More information about the arch-commits mailing list