[arch-commits] Commit in python-simplejson/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 15:40:20
  Author: foutrelis
Revision: 747076

archrelease: copy trunk to community-staging-x86_64

Added:
  python-simplejson/repos/community-staging-x86_64/
  python-simplejson/repos/community-staging-x86_64/PKGBUILD
    (from rev 747075, python-simplejson/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: python-simplejson/repos/community-staging-x86_64/PKGBUILD (from rev 747075, python-simplejson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 15:40:20 UTC (rev 747076)
@@ -0,0 +1,58 @@
+# Maintainer: Alexander Rødseth <rodseth at gmail.com>
+# Contributor: Jaroslav Lichtblau <dragonlord at aur.archlinux.org>
+# Contributor: Allan McRae <allan at archlinux.org>
+# Contributor: David Moore <davidm at sjsoft.com>
+
+pkgbase=python-simplejson
+pkgname=('python-simplejson' 'python2-simplejson')
+pkgver=3.17.2
+pkgrel=2
+pkgdesc='Simple, fast, extensible JSON encoder/decoder for Python'
+license=('MIT')
+arch=('x86_64')
+url='https://github.com/simplejson/simplejson'
+makedepends=('python-setuptools' 'python2-setuptools')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/simplejson/simplejson/archive/v$pkgver.tar.gz")
+sha512sums=('59428640d43fdc6927db752a36196f48d00818a87d924358deab7e498709515423ecdd34dece31364c5e8d64b63d99112fd4a4b8a03b9f9c6533268afc38e314')
+
+prepare() {
+  cp -a simplejson-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/simplejson-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/simplejson-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd "$srcdir"/simplejson-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/simplejson-$pkgver-py2
+  python2 setup.py pytest 
+}
+
+package_python-simplejson() {
+  depends=('python')
+
+  cd simplejson-$pkgver
+  python setup.py install --root="$pkgdir"
+  install -Dm644 "$srcdir"/simplejson-$pkgver/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-simplejson() {
+  depends=('python2')
+
+  cd simplejson-$pkgver-py2
+  python2 setup.py install --root="$pkgdir"
+  install -Dm644 "$srcdir"/simplejson-$pkgver/LICENSE.txt \
+    "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+# vim:set ts=2 sw=2 et:
+