[arch-commits] Commit in python-mpi4py/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 15:49:12
  Author: foutrelis
Revision: 747166

archrelease: copy trunk to community-staging-x86_64

Added:
  python-mpi4py/repos/community-staging-x86_64/
  python-mpi4py/repos/community-staging-x86_64/PKGBUILD
    (from rev 747165, python-mpi4py/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-mpi4py/repos/community-staging-x86_64/PKGBUILD (from rev 747165, python-mpi4py/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 15:49:12 UTC (rev 747166)
@@ -0,0 +1,39 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Anatol Pomozov
+# Contributor: Tim Hütz <tim at huetz.biz>
+# Contributor: Stéphane Gaudreault <stephane at archlinux.org>
+# Contributor: Sebastien Binet <binet at cern.ch>
+
+_pkg=mpi4py
+pkgname=python-${_pkg}
+pkgver=3.0.3
+pkgrel=2
+pkgdesc="Python bindings for the Message Passing Interface (MPI) standard"
+arch=(x86_64)
+url="https://bitbucket.org/mpi4py/mpi4py"
+license=(BSD)
+depends=(python openmpi)
+makedepends=(python-setuptools cython)
+checkdepends=(inetutils)
+source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+sha256sums=('012d716c8b9ed1e513fcc4b18e5af16a8791f51e6d1716baccf988ad355c5a1f')
+
+build() {
+    cd ${_pkg}-${pkgver}
+    python setup.py build
+}
+
+check() {
+    # This is required starting with OpenMPI 3.0 when trying to run more
+    # processes than the number of available cores
+    export OMPI_MCA_rmaps_base_oversubscribe=yes
+
+    cd ${_pkg}-${pkgver}
+    python setup.py test
+}
+
+package() {
+    cd ${_pkg}-${pkgver}
+    python setup.py install --root="${pkgdir}" --skip-build --optimize=1
+    install -Dm644 LICENSE.rst -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}