[arch-commits] Commit in python-yaml/repos (2 files)

[Felix Yan]

    Date: Monday, November 9, 2020 @ 15:53:51
  Author: felixonmars
Revision: 747218

archrelease: copy trunk to community-staging-x86_64

Added:
  python-yaml/repos/community-staging-x86_64/
  python-yaml/repos/community-staging-x86_64/PKGBUILD
    (from rev 747217, python-yaml/trunk/PKGBUILD)

----------+
 PKGBUILD |   64 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

Copied: python-yaml/repos/community-staging-x86_64/PKGBUILD (from rev 747217, python-yaml/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 15:53:51 UTC (rev 747218)
@@ -0,0 +1,64 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Michal Bozon <michal.bozon__at__gmail.com>
+
+pkgbase=python-yaml
+pkgname=(python-yaml python2-yaml)
+pkgver=5.3.1
+pkgrel=3
+pkgdesc='Python bindings for YAML, using fast libYAML library'
+url='https://pyyaml.org/wiki/PyYAML'
+arch=('x86_64')
+license=('MIT')
+makedepends=('python' 'python2' 'libyaml' 'cython' 'cython2')
+source=(https://pyyaml.org/download/pyyaml/PyYAML-${pkgver}.tar.gz)
+sha512sums=('87372877d396bd06cdb6b9052ef8822ef0589a211659bf27d7a1c4deca8429cb39e120a23e5d590d7adc0f8059ce1c8af42409bebd7c6d504d49dc8504d5683a')
+
+prepare() {
+  # Force cython rebuild
+  rm PyYAML-$pkgver/ext/_yaml.c
+
+  cp -a PyYAML-$pkgver{,-py2}
+}
+
+build() {
+  (
+    cd PyYAML-$pkgver
+    python setup.py --with-libyaml build
+  )
+  (
+    cd PyYAML-$pkgver-py2
+    python2 setup.py --with-libyaml build
+  )
+}
+
+check() {
+  (
+    cd PyYAML-$pkgver
+    python -B setup.py test
+  )
+  (
+    cd PyYAML-$pkgver-py2
+    python2 -B setup.py test
+  )
+}
+
+package_python-yaml() {
+  depends=('python' 'libyaml')
+
+  cd PyYAML-$pkgver
+  python setup.py  --with-libyaml install --prefix=/usr --root="${pkgdir}" -O1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+  install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
+}
+
+package_python2-yaml() {
+  depends=('python2' 'libyaml')
+
+  cd PyYAML-$pkgver-py2
+  python2 setup.py --with-libyaml install --prefix=/usr --root="${pkgdir}" -O1 --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+  install -Dm 644 CHANGES README -t "${pkgdir}"/usr/share/doc/${pkgname}
+}
+
+# vim: ts=2 sw=2 et: