[arch-commits] Commit in python-junit-xml/repos (2 files)

Evangelos Foutras foutrelis at archlinux.org
Mon Nov 9 16:26:58 UTC 2020


    Date: Monday, November 9, 2020 @ 16:26:58
  Author: foutrelis
Revision: 747505

archrelease: copy trunk to community-staging-any

Added:
  python-junit-xml/repos/community-staging-any/
  python-junit-xml/repos/community-staging-any/PKGBUILD
    (from rev 747503, python-junit-xml/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-junit-xml/repos/community-staging-any/PKGBUILD (from rev 747503, python-junit-xml/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-09 16:26:58 UTC (rev 747505)
@@ -0,0 +1,38 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-junit-xml
+# The commit that bumps version in setup.py
+_commit=19d3cc333d35dfd2d17d75c506336c15e5c6685a
+pkgver=1.9
+pkgrel=3
+pkgdesc='A Python module for creating JUnit XML test result documents'
+arch=(any)
+url='https://github.com/kyrus/python-junit-xml'
+license=(MIT)
+depends=(python python-six)
+makedepends=(python-setuptools git)
+checkdepends=(python-pytest)
+# There are neither tags nor PyPI source tarball...
+# https://github.com/kyrus/python-junit-xml/issues/68
+source=("git+https://github.com/kyrus/python-junit-xml?signed#commit=$_commit")
+sha256sums=('SKIP')
+validpgpkeys=(
+  '8CCF41209F4D9FB6599E8943B797246363239E88'  # Brian Beyer <brian at redcanary.com>
+)
+
+build() {
+  cd python-junit-xml
+  python setup.py build
+}
+
+check() {
+  cd python-junit-xml
+  pytest -v tests
+}
+
+package() {
+  cd python-junit-xml
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm644 LICENSE.txt -t "$pkgdir"/usr/share/licenses/$pkgname
+}


More information about the arch-commits mailing list