[arch-commits] Commit in flatbuffers/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 16:49:01
  Author: foutrelis
Revision: 747562

archrelease: copy trunk to community-staging-x86_64

Added:
  flatbuffers/repos/community-staging-x86_64/
  flatbuffers/repos/community-staging-x86_64/PKGBUILD
    (from rev 747561, flatbuffers/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: flatbuffers/repos/community-staging-x86_64/PKGBUILD (from rev 747561, flatbuffers/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 16:49:01 UTC (rev 747562)
@@ -0,0 +1,52 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Daichi Shinozaki <dsdseg at gmail.com>
+
+pkgbase=flatbuffers
+pkgname=(flatbuffers python-flatbuffers)
+pkgver=1.12.0
+pkgrel=2
+pkgdesc='An efficient cross platform serialization library for C++, with support for Java, C# and Go'
+arch=(x86_64)
+url='https://google.github.io/flatbuffers/'
+license=(Apache)
+depends=(gcc-libs)
+makedepends=(cmake python-setuptools)
+source=($pkgbase-$pkgver.tar.gz::https://github.com/google/$pkgbase/archive/v$pkgver.tar.gz)
+sha256sums=('62f2223fb9181d1d6338451375628975775f7522185266cd5296571ac152bc45')
+
+prepare() {
+  sed -i 's/-Werror=/-W/g;s/-Werror//g' $pkgname-$pkgver/CMakeLists.txt
+}
+
+build() {
+  cd $pkgbase-$pkgver
+  cmake . \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DFLATBUFFERS_BUILD_FLATLIB=OFF \
+    -DFLATBUFFERS_BUILD_SHAREDLIB=ON
+  make
+
+# Python bindings
+  cd ../$pkgbase-$pkgver/python
+  VERSION=$pkgver python setup.py build
+}
+
+check() {
+  cd $pkgbase-$pkgver
+  make test
+  ./tests/PythonTest.sh
+}
+
+package_flatbuffers() {
+  cd $pkgbase-$pkgver
+  make DESTDIR="$pkgdir" install
+  install -Dm755 flatc -t "$pkgdir"/usr/bin
+}
+
+package_python-flatbuffers() {
+  pkgdesc='An efficient cross platform serialization library for Python'
+  depends=(python)
+
+  cd $pkgbase-$pkgver/python
+  VERSION=$pkgver python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}