[arch-commits] Commit in python-betamax/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 16:51:25
  Author: foutrelis
Revision: 747608

archrelease: copy trunk to community-staging-any

Added:
  python-betamax/repos/community-staging-any/
  python-betamax/repos/community-staging-any/PKGBUILD
    (from rev 747607, python-betamax/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: python-betamax/repos/community-staging-any/PKGBUILD (from rev 747607, python-betamax/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-09 16:51:25 UTC (rev 747608)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-betamax
+pkgname=('python-betamax' 'python2-betamax')
+pkgver=0.8.1
+pkgrel=5
+pkgdesc="A VCR imitation for python-requests"
+arch=('any')
+license=('GPL')
+url='https://github.com/sigmavirus24/betamax'
+makedepends=('python-setuptools' 'python2-setuptools' 'python-requests' 'python2-requests')
+checkdepends=('python-pytest-runner' 'python2-pytest-runner' 'python2-mock')
+source=("$pkgbase-$pkgver.tar.gz::https://github.com/sigmavirus24/betamax/archive/$pkgver.tar.gz"
+        betamax-pytest4.patch::"https://github.com/betamaxpy/betamax/commit/165cc321.patch")
+sha512sums=('3888aa5f1e249faf496a32c03fb7d37096d7bbde573048c2ff3d1ba0fa03ebaeb4ff4e72191478da5f1a04d813204e31d3897469bd5f5eea4c5db2c72aae1374'
+            '258bd6729286dc9374829308c23cca73ea640c4597ca8747ebb8281bcf7723bba3dfee5b55cadff0459e8dc4511d85228d37911e981859dd0af55a3753ae9e22')
+
+prepare() {
+  (cd betamax-$pkgver
+   patch -p1 -i ../betamax-pytest4.patch # Fix tests with pytest 4
+  )
+  cp -a betamax-$pkgver{,-py2}
+}
+
+check() {
+  cd "$srcdir"/betamax-$pkgver
+  python setup.py pytest
+
+  cd "$srcdir"/betamax-$pkgver-py2
+  python2 setup.py pytest
+}
+
+package_python-betamax() {
+  depends=('python-requests')
+
+  cd betamax-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-betamax() {
+  depends=('python2-requests')
+
+  cd betamax-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}