[arch-commits] Commit in asciidoc/repos (2 files)

[Felix Yan]

    Date: Monday, November 9, 2020 @ 16:51:52
  Author: felixonmars
Revision: 747623

archrelease: copy trunk to community-staging-any

Added:
  asciidoc/repos/community-staging-any/
  asciidoc/repos/community-staging-any/PKGBUILD
    (from rev 747621, asciidoc/trunk/PKGBUILD)

----------+
 PKGBUILD |   60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 60 insertions(+)

Copied: asciidoc/repos/community-staging-any/PKGBUILD (from rev 747621, asciidoc/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-09 16:51:52 UTC (rev 747623)
@@ -0,0 +1,60 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+# Contributor: Florian Pritz <flo at xinu.at>
+# Contributor: Chris Brannon <cmbrannon79 at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy at archlinux.org>
+# Contributor: Dan McGee <dan at archlinux.org>
+# Contributor: Jaroslaw Rosiek <philosoph at interia.pl>
+# Contributor: Darwin Bautista <djclue917 at gmail.com>
+# Contributor: Daniel J Griffiths <ghost1227 at archlinux.us>
+
+pkgname=asciidoc
+pkgver=9.0.3
+pkgrel=2
+pkgdesc='Text document format for short documents, articles, books and UNIX man pages.'
+arch=('any')
+url='https://asciidoc.org/'
+license=('GPL')
+depends=('python' 'libxslt' 'docbook-xsl')
+checkdepends=('dblatex' 'graphviz' 'lilypond' 'source-highlight')
+optdepends=('graphviz: graphviz-filter'
+            'lilypond: music-filter'
+            'imagemagick: music-filter'
+            'source-highlight: source-highlight-filter'
+            'dblatex: pdf generation'
+            'fop: alternative pdf generation'
+            'w3m: text generation'
+            'lynx: alternative text generation')
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/asciidoc/asciidoc-py3/archive/${pkgver}.tar.gz")
+sha256sums=('c0de1dcf111a200bf85bd81f67bc18778f839e55d761d6c7320095985524853a')
+b2sums=('4e196bddfe400c3758086048089e3d316a8e7909f870b761e23506de8cd5b9871df8a0e1017fafbaa854711ab0d49efe4f8134453c02528ba8b6e1ac1cf0c0ff')
+
+prepare() {
+  cd ${pkgname}-py3-${pkgver}
+
+  autoconf
+}
+
+build() {
+  cd ${pkgname}-py3-${pkgver}
+
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc
+  make manpages
+}
+
+check() {
+  cd ${pkgname}-py3-${pkgver}
+
+  make test
+}
+
+package() {
+  cd ${pkgname}-py3-${pkgver}
+
+  make install DESTDIR="${pkgdir}"
+  make docs DESTDIR="${pkgdir}"
+
+  install -Dm644 asciidocapi.py \
+    "${pkgdir}/$(python -c 'import sysconfig; print(sysconfig.get_paths()["platlib"])')"/asciidocapi.py
+}