[arch-commits] Commit in python-websockets/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 18:16:50
  Author: foutrelis
Revision: 747921

archrelease: copy trunk to community-staging-x86_64

Added:
  python-websockets/repos/community-staging-x86_64/
  python-websockets/repos/community-staging-x86_64/PKGBUILD
    (from rev 747920, python-websockets/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-websockets/repos/community-staging-x86_64/PKGBUILD (from rev 747920, python-websockets/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 18:16:50 UTC (rev 747921)
@@ -0,0 +1,38 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Sherlock Holo <sherlockya at gmail.com>
+# Contributor: user6553591 <Message on Reddit>
+
+pkgname=python-websockets
+pkgver=8.1
+pkgrel=2
+pkgdesc='Python implementation of the WebSocket Protocol (RFC 6455)'
+url='https://github.com/aaugustin/websockets'
+arch=('x86_64')
+license=('BSD')
+depends=('python')
+makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx-autodoc-typehints' 'python-sphinxcontrib-trio')
+source=(https://github.com/aaugustin/websockets/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('d245702574cf513da54bfc0ca10768558cd4e5017ecf8cb647f4b9176561192a3ace64edfc5c6f735664bf1b6136aa0bb9828114478f92d2c051e3109a218c12')
+
+build() {
+  cd websockets-${pkgver}
+  python setup.py build
+  sphinx-build -b text docs docs/_build/text
+  sphinx-build -b man docs docs/_build/man
+}
+
+check() {
+  cd websockets-${pkgver}
+  python setup.py test
+}
+
+package() {
+  cd websockets-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/websockets.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: