[arch-commits] Commit in python-pep517/repos (staging-any staging-any/PKGBUILD)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 18:19:14
  Author: foutrelis
Revision: 399879

archrelease: copy trunk to staging-any

Added:
  python-pep517/repos/staging-any/
  python-pep517/repos/staging-any/PKGBUILD
    (from rev 399878, python-pep517/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: python-pep517/repos/staging-any/PKGBUILD (from rev 399878, python-pep517/trunk/PKGBUILD)
===================================================================
--- staging-any/PKGBUILD	                        (rev 0)
+++ staging-any/PKGBUILD	2020-11-09 18:19:14 UTC (rev 399879)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-pep517
+pkgname=('python-pep517' 'python2-pep517')
+pkgver=0.9.1
+pkgrel=2
+pkgdesc="Wrappers to build Python packages using PEP 517 hooks"
+arch=('any')
+license=('MIT')
+url="https://github.com/takluyver/pep517"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-toml' 'python2-toml'
+             'python2-importlib-metadata' 'python2-zipp')
+checkdepends=('python-mock' 'python-pytest-flake8' 'python-testpath' 'python-pip')
+source=("https://pypi.io/packages/source/p/pep517/pep517-$pkgver.tar.gz")
+sha512sums=('7c7d181d52a6d042ad432c4366021f9b2364c77193d99066668acd4c6967dab299644febf0dc4a6efb9a777a0aaae7df2687191cba3f3b93e6bf06ee0769a7df')
+
+prepare() {
+  cp -a pep517-$pkgver{,-py2}
+}
+
+build() {
+  cd "$srcdir"/pep517-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/pep517-$pkgver-py2
+  python2 setup.py build
+}
+
+check() {
+  cd pep517-$pkgver
+  # https://github.com/pypa/pep517/issues/35
+  pytest --deselect setup.py
+}
+
+package_python-pep517() {
+  depends=('python-toml')
+
+  cd pep517-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}
+
+package_python2-pep517() {
+  depends=('python2-toml' 'python2-importlib-metadata' 'python2-zipp')
+
+  cd pep517-$pkgver-py2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}