[arch-commits] Commit in python-cryptography/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 18:20:24
  Author: foutrelis
Revision: 399885

archrelease: copy trunk to staging-x86_64

Added:
  python-cryptography/repos/staging-x86_64/
  python-cryptography/repos/staging-x86_64/PKGBUILD
    (from rev 399884, python-cryptography/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: python-cryptography/repos/staging-x86_64/PKGBUILD (from rev 399884, python-cryptography/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-11-09 18:20:24 UTC (rev 399885)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=python-cryptography
+pkgname=('python-cryptography' 'python2-cryptography')
+pkgver=3.2.1
+pkgrel=2
+pkgdesc="A package designed to expose cryptographic recipes and primitives to Python developers"
+arch=('x86_64')
+license=('Apache')
+url="https://pypi.python.org/pypi/cryptography"
+makedepends=('python-setuptools' 'python2-setuptools' 'python-six' 'python2-six' 'python-cffi'
+             'python2-cffi' 'python2-enum34' 'python-pyasn1' 'python2-pyasn1' 'python-idna'
+             'python2-idna' 'python2-ipaddress' 'python-asn1crypto' 'python2-asn1crypto')
+checkdepends=('python-pytest-runner' "python-cryptography-vectors=$pkgver" 'python-iso8601'
+              'python-pretend' 'python-hypothesis' 'python-pytz')
+source=("https://pypi.io/packages/source/c/cryptography/cryptography-$pkgver.tar.gz")
+sha512sums=('e3f1806693c24aadc3ef0df374ce1845760e87ad7c243226b75e80820b50bdc0760e4bb5f6ce26d62a6d23736b3109f72cd30b52ae2a36b26ec5656ec96c6175')
+
+prepare() {
+  cp -a cryptography-${pkgver}{,-python2}
+}
+
+build() {
+  cd "$srcdir"/cryptography-$pkgver
+  python setup.py build
+
+  cd "$srcdir"/cryptography-$pkgver-python2
+  python2 setup.py build
+}
+
+check() {
+  cd cryptography-$pkgver
+  python setup.py pytest
+}
+
+package_python-cryptography() {
+  depends=('python-six' 'python-cffi' 'python-idna' 'python-setuptools' 'python-asn1crypto')
+
+  cd cryptography-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}
+
+package_python2-cryptography() {
+  depends=('python2-six' 'python2-cffi' 'python2-enum34' 'python2-idna' 'python2-ipaddress'
+           'python2-setuptools' 'python2-asn1crypto')
+
+  cd cryptography-$pkgver-python2
+  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}