[arch-commits] Commit in libolm/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 18:20:35
  Author: foutrelis
Revision: 747979

archrelease: copy trunk to community-staging-x86_64

Added:
  libolm/repos/community-staging-x86_64/
  libolm/repos/community-staging-x86_64/PKGBUILD
    (from rev 747978, libolm/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: libolm/repos/community-staging-x86_64/PKGBUILD (from rev 747978, libolm/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 18:20:35 UTC (rev 747979)
@@ -0,0 +1,56 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=('libolm' 'python-olm')
+pkgver=3.2.1
+_tag=365aa5513c9845ad314aaee87cda4a683d2e8638 # git rev-parse "$pkgver"
+pkgrel=2
+pkgdesc='Implementation of the Olm and Megolm cryptographic ratchets'
+arch=('x86_64')
+url='https://gitlab.matrix.org/matrix-org/olm'
+license=('APACHE')
+makedepends=('git' 'cmake' 'python' 'python-cffi' 'python-future' 'python-setuptools')
+checkdepends=('python-aspectlib' 'python-pytest' 'python-pytest-benchmark')
+source=("git+$url.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=('56CF24AEE5F4513280CC594BF75FDC22C1DE8453') # Matrix.org olm <olm at matrix.org>
+
+pkgver() {
+	cd olm
+	git describe | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
+build() {
+	cd olm
+	cmake -DCMAKE_INSTALL_PREFIX=/usr \
+	      -DCMAKE_BUILD_TYPE=None \
+	      -DCMAKE_C_FLAGS="${CFLAGS} ${CPPFLAGS}" \
+	      -DCMAKE_CXX_FLAGS="${CXXFLAGS} ${CPPFLAGS}" \
+	      -B build
+	cmake --build build
+
+	cd python
+	make olm-python3
+}
+
+check() {
+	cd olm/build/tests
+	ctest
+
+	cd ../../python
+	PYTHONPATH="$(find build -name 'lib.*' -type d -print)" LD_LIBRARY_PATH=../build python -m pytest
+}
+
+package_libolm() {
+	depends=('gcc-libs')
+	provides=('libolm.so')
+
+	cd olm/build
+	make DESTDIR="$pkgdir" install
+}
+
+package_python-olm() {
+	pkgdesc='Python bindings for Olm'
+	depends=('libolm' 'python' 'python-cffi' 'python-future' 'libolm.so')
+
+	cd olm/python
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+}