[arch-commits] Commit in shiboken2/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Felix Yan felixonmars at archlinux.org
Mon Nov 9 18:21:06 UTC 2020


    Date: Monday, November 9, 2020 @ 18:21:06
  Author: felixonmars
Revision: 399887

archrelease: copy trunk to staging-x86_64

Added:
  shiboken2/repos/staging-x86_64/
  shiboken2/repos/staging-x86_64/PKGBUILD
    (from rev 399886, shiboken2/trunk/PKGBUILD)

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Copied: shiboken2/repos/staging-x86_64/PKGBUILD (from rev 399886, shiboken2/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2020-11-09 18:21:06 UTC (rev 399887)
@@ -0,0 +1,48 @@
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=shiboken2
+pkgname=(shiboken2 python-shiboken2)
+_qtver=5.15.1
+_clangver=11.0.0
+pkgver=${_qtver/-/}
+pkgrel=3
+arch=(x86_64)
+url='https://www.qt.io'
+license=(GPL2 LGPL)
+pkgdesc='Generates bindings for C++ libraries using CPython source code'
+makedepends=(clang llvm cmake libxslt qt5-xmlpatterns python-sphinx)
+_pkgfqn=pyside-setup-opensource-src-$_qtver
+source=("https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-$pkgver-src/${_pkgfqn}.tar.xz")
+sha256sums=('f175c1d8813257904cf0efeb58e44f68d53b9916f73adaf9ce19514c0271c3fa')
+
+prepare() {
+  mkdir -p build
+}
+
+build() {
+  cd build
+  cmake ../${_pkgfqn}/sources/shiboken2 \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_TESTS=OFF \
+    -DUSE_PYTHON_VERSION=3
+  make
+}
+
+package_shiboken2() {
+  depends=(clang=$_clangver llvm libxslt qt5-xmlpatterns)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+# Provided in python-shiboken2
+  rm -r "$pkgdir"/usr/lib/{python*,libshiboken*}
+}
+
+package_python-shiboken2() {
+  depends=(python)
+
+  cd build
+  make DESTDIR="$pkgdir" install
+# Provided in shiboken2
+  rm -r "$pkgdir"/usr/{bin,include,lib/{cmake,pkgconfig}}
+}



More information about the arch-commits mailing list