[arch-commits] Commit in ansible-base/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 19:24:08
  Author: foutrelis
Revision: 748060

archrelease: copy trunk to community-staging-any

Added:
  ansible-base/repos/community-staging-any/
  ansible-base/repos/community-staging-any/PKGBUILD
    (from rev 748057, ansible-base/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: ansible-base/repos/community-staging-any/PKGBUILD (from rev 748057, ansible-base/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-09 19:24:08 UTC (rev 748060)
@@ -0,0 +1,45 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
+# Contributor: Chris <seitz.christoph at gmail.com>
+# Contributor: m0ikz <ndelatorre at moikz.com.ar>
+# Contributor: atweiden <archbaum at gmail.com>
+
+pkgname=ansible-base
+pkgver=2.10.3
+pkgrel=2
+pkgdesc='Radically simple IT automation platform'
+arch=('any')
+url='https://pypi.org/project/ansible-base/'
+license=('GPL3')
+depends=('python' 'python-yaml' 'python-paramiko' 'python-jinja')
+provides=('python-ansible')
+optdepends=('sshpass: for ssh connections with password'
+            'python-passlib: crypt values for vars_prompt'
+            'python-netaddr: for the ipaddr filter'
+            'python-systemd: log to journal'
+            'python-pywinrm: connect to Windows machines'
+            'python-dnspython: for dig lookup'
+            'python-jmespath: json_query support')
+makedepends=('python-setuptools')
+backup=('etc/ansible/ansible.cfg')
+source=("https://pypi.python.org/packages/source/a/ansible-base/ansible-base-${pkgver}.tar.gz")
+sha512sums=('4da2c79c7d990bbe07e136447643484d947e512693194017623deadd88d6556dac67865069182059ae2daf82a13876600dc5472712d6ab6e0556cb829fce3b5b')
+
+build() {
+  cd ansible-base-${pkgver}
+  python setup.py build
+}
+
+package() {
+  cd ansible-base-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}"
+  install -Dm644 COPYING "${pkgdir}"/usr/share/doc/${pkgname}/COPYING
+
+  install -d "${pkgdir}"/usr/share/ansible/doc
+  cp -dpr --no-preserve=ownership ./examples "${pkgdir}"/usr/share/ansible/doc/
+  install -Dm644 examples/ansible.cfg "${pkgdir}"/etc/ansible/ansible.cfg
+
+  install -d "${pkgdir}"/usr/share/man/man1
+  cp -dpr --no-preserve=ownership docs/man/man1/*.1 "${pkgdir}"/usr/share/man/man1
+}