[arch-commits] Commit in python-ujson/repos (2 files)

[Evangelos Foutras]

    Date: Monday, November 9, 2020 @ 19:53:12
  Author: foutrelis
Revision: 748095

archrelease: copy trunk to community-staging-x86_64

Added:
  python-ujson/repos/community-staging-x86_64/
  python-ujson/repos/community-staging-x86_64/PKGBUILD
    (from rev 748093, python-ujson/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-ujson/repos/community-staging-x86_64/PKGBUILD (from rev 748093, python-ujson/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-09 19:53:12 UTC (rev 748095)
@@ -0,0 +1,39 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Maintainer: Massimiliano Torromeo <massimiliano.torromeo at gmail.com>
+
+pkgname=python-ujson
+_pkgname=ultrajson
+pkgver=4.0.1
+pkgrel=2
+pkgdesc="Ultra fast JSON encoder and decoder for Python"
+url="https://github.com/ultrajson/ultrajson"
+arch=('x86_64')
+license=('BSD')
+depends=('python')
+makedepends=('python-setuptools-scm' 'python-pip')
+checkdepends=('python-six' 'python-pytest')
+source=(https://github.com/ultrajson/ultrajson/archive/$pkgver/$pkgname-$pkgver.tar.gz)
+sha512sums=('583ec226ccd44667e41af5e0dff5a6912847fc9e3befdb11ac520cd7c6b9d20012a325e8931a9601268f261c2bfe82fcbffa829666559c8700aaafab3fc11c2f')
+b2sums=('15e501138dce9c7e3c7360d0f03583d6744b8b1888f4cd00980de508a6c2fd6d7002dfd2cce1f7b5d3b14f61828149397357957e31e4e1a79abb8e6bc1d1f602')
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}
+  local PYTHONVERSION="$(python -c 'import sys; print("{}.{}".format(sys.version_info.major, sys.version_info.minor))')"
+  PYTHONPATH="build/lib.linux-${CARCH}-${PYTHONVERSION}" pytest
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py install --skip-build -O1 --root="${pkgdir}"
+  install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: