[arch-commits] Commit in python-faker/repos (2 files)

[Felix Yan]

    Date: Monday, November 9, 2020 @ 19:55:56
  Author: felixonmars
Revision: 748128

archrelease: copy trunk to community-staging-any

Added:
  python-faker/repos/community-staging-any/
  python-faker/repos/community-staging-any/PKGBUILD
    (from rev 748127, python-faker/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: python-faker/repos/community-staging-any/PKGBUILD (from rev 748127, python-faker/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-09 19:55:56 UTC (rev 748128)
@@ -0,0 +1,41 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Jeremy "Ichimonji10" Audet <ichimonji10 at gmail dot com>
+# Contributor: dnuux <dnuuxx at gmail.com>
+
+pkgname=python-faker
+pkgver=4.14.2
+pkgrel=2
+pkgdesc='Faker generates fake data for you.'
+arch=('any')
+url='https://faker.readthedocs.io/en/master/'
+license=('MIT')
+provides=("python-fake-factory=$pkgver")
+conflicts=('python-fake-factory')
+replaces=('python-fake-factory')
+depends=('python-setuptools' 'python-dateutil' 'python-text-unidecode')
+makedepends=('python-pip' 'python-wheel' 'python-pytest-runner')
+checkdepends=('python-validators' 'python-ukpostcodeparser' 'python-random2'
+              'python-freezegun')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/joke2k/faker/archive/v$pkgver.tar.gz")
+sha512sums=('d425c2995fd48c4d07bf89cb7bf35372494cd7beb183fcde4eab4e96686dd87aca84460042d1cc0d7022902e1aae366c3dd4b8afd88fa97cb2275603d0bb3ff6')
+
+prepare() {
+  sed -i -e 's/==/>=/' faker-$pkgver/setup.py
+}
+
+build() {
+  cd faker-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd faker-$pkgver
+  python setup.py egg_info
+  python -m pytest
+}
+
+package() {
+  cd faker-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+  install -Dm 644 LICENSE.txt "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE.txt
+}