[arch-commits] Commit in python-gevent-websocket/repos (2 files)

[Felix Yan]

    Date: Monday, November 9, 2020 @ 20:20:07
  Author: felixonmars
Revision: 748189

archrelease: copy trunk to community-staging-any

Added:
  python-gevent-websocket/repos/community-staging-any/
  python-gevent-websocket/repos/community-staging-any/PKGBUILD
    (from rev 748188, python-gevent-websocket/trunk/PKGBUILD)

----------+
 PKGBUILD |   37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

Copied: python-gevent-websocket/repos/community-staging-any/PKGBUILD (from rev 748188, python-gevent-websocket/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-09 20:20:07 UTC (rev 748189)
@@ -0,0 +1,37 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: minus <minus at mnus.de>
+
+_pkgname=gevent-websocket
+pkgname=python-${_pkgname}
+pkgver=0.10.1
+pkgrel=5
+pkgdesc='WebSocket library for the gevent networking library'
+url='https://www.gitlab.com/noppo/gevent-websocket'
+arch=('any')
+license=('Apache')
+depends=('python' 'python-gevent' 'gunicorn' 'python-ujson')
+makedepends=('cython' 'python-setuptools' 'python-sphinx')
+source=(https://gitlab.com/noppo/gevent-websocket/-/archive/${pkgver}/gevent-websocket-${pkgver}.tar.gz)
+sha512sums=('33473bd20bf8bdab95784bc46093c4f3567d61290731e1980de3b8bf96d71976dca658547320329d5ee5291f54e423a1c7ae8300358bc641eae3c71a1943ea84')
+
+prepare() {
+  cd ${_pkgname}-${pkgver}
+  sed -E "s|release = .*|release = '${pkgver}'|" -i docs/conf.py
+}
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py build
+  sphinx-build -b text docs docs/_build/text
+  sphinx-build -b man docs docs/_build/man
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/gevent-websocket.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+
+# vim: ts=2 sw=2 et: