[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, November 9, 2020 @ 20:50:11
  Author: felixonmars
Revision: 748242

addpkg: haskell-tasty-kat 0.0.3-1

Added:
  haskell-tasty-kat/
  haskell-tasty-kat/repos/
  haskell-tasty-kat/trunk/
  haskell-tasty-kat/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: haskell-tasty-kat/trunk/PKGBUILD
===================================================================
--- haskell-tasty-kat/trunk/PKGBUILD	                        (rev 0)
+++ haskell-tasty-kat/trunk/PKGBUILD	2020-11-09 20:50:11 UTC (rev 748242)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=tasty-kat
+pkgname=haskell-tasty-kat
+pkgver=0.0.3
+pkgrel=1
+pkgdesc="Known Answer Tests (KAT) framework for tasty"
+url="https://github.com/vincenthz/tasty-kat"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-tasty')
+makedepends=('ghc' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('a72501f0f77db372648566bbba1dd1d6d0d0c975b42238875d663313e9a5db93')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}