[arch-commits] Commit in python-zope-security/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 10, 2020 @ 04:04:13
  Author: foutrelis
Revision: 748436

archrelease: copy trunk to community-staging-x86_64

Added:
  python-zope-security/repos/community-staging-x86_64/
  python-zope-security/repos/community-staging-x86_64/PKGBUILD
    (from rev 748435, python-zope-security/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: python-zope-security/repos/community-staging-x86_64/PKGBUILD (from rev 748435, python-zope-security/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-10 04:04:13 UTC (rev 748436)
@@ -0,0 +1,38 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=python-zope-security
+pkgver=5.1.1
+pkgrel=2
+pkgdesc="Zope Security Framework"
+arch=('x86_64')
+url="https://github.com/zopefoundation/zope.security"
+license=('ZPL')
+depends=('python-setuptools' 'python-zope-component' 'python-zope-i18nmessageid'
+         'python-zope-interface' 'python-zope-location' 'python-zope-proxy' 'python-zope-schema')
+checkdepends=('python-btrees' 'python-nose' 'python-zope-configuration' 'python-zope-testing'
+              'python-zope-testrunner')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/zopefoundation/zope.security/archive/$pkgver.tar.gz")
+sha512sums=('b23c7d489be3e60a1e88f9ef67fe133273318fc67b28222124c51981eb76ef11b0783662ec90f206867010dc120ce914dac45c6a6fd6edc925de2c9da0ad0b38')
+
+prepare() {
+  cd zope.security-$pkgver
+  # TODO
+  sed -i '/def test_iteration_of_btree_items_keys_values/i \    @unittest.skip("Circular import weirdness")' src/zope/security/tests/test_checker.py
+}
+
+build() {
+  cd zope.security-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd zope.security-$pkgver
+  PYTHONPATH="$PWD/build/lib.linux-$CARCH-3.9:$PYTHONPATH" python -m zope.testrunner --test-path=src
+}
+
+package() {
+  cd zope.security-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1
+}
+
+# vim:set ts=2 sw=2 et: