[arch-commits] Commit in python-spyder-kernels/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 10, 2020 @ 04:06:24
  Author: foutrelis
Revision: 748486

archrelease: copy trunk to community-staging-any

Added:
  python-spyder-kernels/repos/community-staging-any/
  python-spyder-kernels/repos/community-staging-any/PKGBUILD
    (from rev 748484, python-spyder-kernels/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: python-spyder-kernels/repos/community-staging-any/PKGBUILD (from rev 748484, python-spyder-kernels/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 04:06:24 UTC (rev 748486)
@@ -0,0 +1,52 @@
+# Maintainer: Muflone http://www.muflone.com/contacts/english/
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkg=spyder-kernels
+pkgname=python-${_pkg}
+pkgver=1.9.4
+pkgrel=2
+pkgdesc="Jupyter Kernels for the Spyder console"
+arch=(any)
+url="https://github.com/spyder-ide/spyder-kernels/"
+license=(MIT)
+makedepends=(python python-setuptools)
+depends=(
+    python-cloudpickle
+    python-ipykernel
+    python-jupyter_client
+    python-pyzmq
+    python-wurlitzer
+)
+checkdepends=(
+    cython
+    python-dask
+    python-distributed
+    python-flaky
+    python-matplotlib
+    python-mock
+    python-numpy
+    python-pandas
+    python-pytest
+    python-scipy
+    python-xarray
+)
+# No tests in pypi tarballs
+#source=(https://files.pythonhosted.org/packages/source/${_pkg::1}/${_pkg}/${_pkg}-${pkgver}.tar.gz)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('e2b9dd053a6532329db56267b245bb1b739fdc9b9cfd3555b2faf1948c761951')
+
+build() {
+  cd ${_pkg}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkg}-${pkgver}
+  pytest spyder_kernels
+}
+
+package() {
+  cd ${_pkg}-${pkgver}
+  python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}