[arch-commits] Commit in python-starlette/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 10, 2020 @ 04:57:51
  Author: foutrelis
Revision: 749199

archrelease: copy trunk to community-staging-any

Added:
  python-starlette/repos/community-staging-any/
  python-starlette/repos/community-staging-any/PKGBUILD
    (from rev 749198, python-starlette/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-starlette/repos/community-staging-any/PKGBUILD (from rev 749198, python-starlette/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 04:57:51 UTC (rev 749199)
@@ -0,0 +1,54 @@
+# Maintainer: Filipe Laíns (FFY00) <lains at archlinux.org>
+
+_pkgname=starlette
+pkgname=python-$_pkgname
+pkgver=0.13.8
+pkgrel=2
+pkgdesc='The little ASGI framework that shines'
+arch=('any')
+url='https://github.com/encode/starlette'
+license=('BSD')
+depends=('python')
+optdepends=('python-aiofiles' 'python-graphene' 'python-itsdangerous' 'python-jinja'
+            'python-yaml' 'python-requests' 'python-ujson')
+makedepends=('python-setuptools')
+checkdepends=('python-pytest-runner'
+              'python-aiofiles' 'python-graphene' 'python-itsdangerous' 'python-jinja'
+              'python-yaml' 'python-requests' 'python-ujson'
+              'python-unidecode')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('362d5422868aa8541406e8d69a408bc5acdd64989c5f63e6fe3119a2e842eea248bb8646af9c9e0ac35c5c59a91ee1ff15d064c74d7f760ae536193e13ae9ced')
+
+prepare() {
+  cd $_pkgname-$pkgver
+
+  # needs python-multipart
+  rm tests/test_formparsers.py
+
+  # needs python-databases
+  rm tests/test_database.py
+
+  # needs a different graphql version
+  rm tests/test_graphql.py
+}
+
+build() {
+  cd $_pkgname-$pkgver
+
+  python setup.py build
+}
+
+check() {
+  cd $_pkgname-$pkgver
+
+  # test_request_form_urlencoded needs python-multipart
+  python setup.py pytest --addopts -k-test_request_form_urlencoded
+}
+
+package() {
+  cd $_pkgname-$pkgver
+
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  install -Dm 644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}