[arch-commits] Commit in python-authlib/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 10, 2020 @ 05:00:10
  Author: felixonmars
Revision: 749222

archrelease: copy trunk to community-staging-any

Added:
  python-authlib/repos/community-staging-any/
  python-authlib/repos/community-staging-any/PKGBUILD
    (from rev 749220, python-authlib/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: python-authlib/repos/community-staging-any/PKGBUILD (from rev 749220, python-authlib/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 05:00:10 UTC (rev 749222)
@@ -0,0 +1,54 @@
+# Maintainer: Eli Schwartz <eschwartz at archlinux.org>
+
+_pkgname=authlib
+pkgname=python-authlib
+pkgver=0.15.2
+_commit=1969b567733f6426e5a8e20c5edf3371e9d23e5c
+pkgrel=2
+pkgdesc="The ultimate Python library in building OAuth and OpenID Connect servers"
+arch=('any')
+url="https://github.com/lepture/${_pkgname}"
+license=('BSD')
+depends=('python-cryptography')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest-asyncio' 'python-pytest-django' 'python-requests'
+              'python-django' 'python-flask-sqlalchemy' 'python-httpx' 'python-starlette')
+source=("git+${url}.git#commit=${_commit}?signed")
+b2sums=('SKIP')
+validpgpkeys=('72F8E895A70CEBDF4F2ADFE07E55E3E0118B2B4C') # Hsiaoming (UJET) <lepture at ujet.co>
+
+pkgver() {
+    cd "${srcdir}"/${_pkgname}
+
+    git describe --exact-match --tags | sed 's/^v//'
+}
+
+prepare() {
+    cd "${srcdir}"/${_pkgname}
+
+    # no need to install an additional copy of the stdlib
+    find tests -name \*.py -exec sed -i 's/^import mock$/from unittest import mock/' {} +
+}
+
+build() {
+    cd "${srcdir}"/${_pkgname}
+
+    python setup.py build
+}
+
+check() {
+    cd "${srcdir}"/${_pkgname}
+
+    # Some tests fail is run with Django with Flask tests
+    # https://github.com/lepture/authlib/issues/284
+    python -m pytest --ignore tests/django --ignore tests/flask
+    python -m pytest tests/django
+    python -m pytest tests/flask
+}
+
+package() {
+    cd "${srcdir}"/${_pkgname}
+
+    python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+    install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}