[arch-commits] Commit in python-stem/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 10, 2020 @ 05:01:47
  Author: foutrelis
Revision: 749240

archrelease: copy trunk to community-staging-any

Added:
  python-stem/repos/community-staging-any/
  python-stem/repos/community-staging-any/PKGBUILD
    (from rev 749239, python-stem/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: python-stem/repos/community-staging-any/PKGBUILD (from rev 749239, python-stem/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 05:01:47 UTC (rev 749240)
@@ -0,0 +1,47 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Spider.007 <archlinux AT spider007 DOT net>
+
+pkgname=python-stem
+_pypiname=${pkgname#*-}
+pkgver=1.8.0
+pkgrel=2
+pkgdesc='Python controller library for Tor'
+url='https://stem.torproject.org/'
+arch=('any')
+license=('LGPL3')
+depends=('python' 'python-cryptography' 'python-pynacl' 'procps-ng')
+checkdepends=('tor' 'python-mock')
+optdepends=('tor: tor-server to talk to')
+replaces=('stem')
+provides=('stem')
+source=(https://files.pythonhosted.org/packages/source/${_pypiname::1}/${_pypiname}/${_pypiname}-${pkgver}.tar.gz{,.asc})
+sha256sums=('a0b48ea6224e95f22aa34c0bc3415f0eb4667ddeae3dfb5e32a6920c185568c2'
+            'SKIP')
+validpgpkeys=('68278CC5DD2D1E85C4E45AD90445B7AB9ABBEEC6') # Damian Johnson (www.atagar.com) <atagar1 at gmail.com>
+
+prepare() {
+  cd ${_pypiname}-${pkgver}
+  # remove flaky integration tests
+  sed -i test/settings.cfg \
+    -e '/|test.integ.client.connection.TestConnection/d' \
+    -e '/|test.integ.process.TestProcess/d' \
+    -e '/|test.integ.installation.TestInstallation/d'
+  rm test/integ/{client/connection,{installation,process}}.py
+}
+
+build() {
+  cd ${_pypiname}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pypiname}-${pkgver}
+  ./run_tests.py --all
+}
+
+package() {
+  cd ${_pypiname}-${pkgver}
+  python setup.py install --optimize=1 --root="${pkgdir}" --skip-build
+}
+
+# vim: ts=2 sw=2 et: