[arch-commits] Commit in ropgadget/repos (2 files)

[Evangelos Foutras]

    Date: Tuesday, November 10, 2020 @ 05:02:04
  Author: foutrelis
Revision: 749247

archrelease: copy trunk to community-staging-any

Added:
  ropgadget/repos/community-staging-any/
  ropgadget/repos/community-staging-any/PKGBUILD
    (from rev 749246, ropgadget/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: ropgadget/repos/community-staging-any/PKGBUILD (from rev 749246, ropgadget/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 05:02:04 UTC (rev 749247)
@@ -0,0 +1,38 @@
+# Maintainer: Levente Polyak <levente[at]leventepolyak[dot]net>
+# Contributor: s1gma <s1gma at mindslicer.com>
+
+pkgname=ropgadget
+_pkgname=ROPgadget
+pkgver=6.3
+pkgrel=2
+pkgdesc='Search gadgets in binaries to facilitate ROP exploitation for several file formats and architectures'
+url='http://www.shell-storm.org/project/ROPgadget'
+arch=('any')
+license=('GPL2')
+depends=('python-capstone')
+makedepends=('python-setuptools')
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/JonathanSalwan/${_pkgname}/archive/v${pkgver}.tar.gz)
+sha512sums=('5c39e3e665d498fb7567060c81d3d48819598cfe92959e08d6d27737beb4b92207cd14a15551dc9f7cb987ec1dbd80089820ea5397793b2013eb2eb4295ea184')
+
+prepare() {
+  cd ${_pkgname}-${pkgver}
+  sed 's|python2|python|g' -i ropgadget/**/*.py ropgadget/*/*/*.py
+}
+
+build() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py build
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}
+  ./ROPgadget.py --binary ./test-suite-binaries/elf-Linux-x86 --string "main"
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+  python setup.py install -O1 --root="${pkgdir}" --prefix=/usr
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+}
+
+# vim:set ts=2 sw=2 et: