[arch-commits] Commit in python-jsbeautifier/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 10, 2020 @ 05:04:09
  Author: felixonmars
Revision: 749271

archrelease: copy trunk to community-staging-any

Added:
  python-jsbeautifier/repos/community-staging-any/
  python-jsbeautifier/repos/community-staging-any/PKGBUILD
    (from rev 749269, python-jsbeautifier/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: python-jsbeautifier/repos/community-staging-any/PKGBUILD (from rev 749269, python-jsbeautifier/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 05:04:09 UTC (rev 749271)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Daniel M. Capella <polyzen at archlinux.org>
+
+pkgname=('python-jsbeautifier' 'python-cssbeautifier')
+pkgbase=python-jsbeautifier
+pkgver=1.13.0
+pkgrel=2
+arch=('any')
+license=('MIT')
+url='https://github.com/beautify-web/js-beautify'
+depends=('python-setuptools' 'python-six' 'python-editorconfig')
+source=("https://github.com/beautify-web/js-beautify/archive/v$pkgver/js-beautify-v$pkgver.tar.gz")
+sha512sums=('a60a71f8ef1b3751ab32fa5884bc07d46f2f02ce06d3527e15ef4d709eae625677b31a69990e56da859ad6c72aefe41992155cfaaeea8590dd505003ccfd7979')
+
+prepare() {
+  cd js-beautify-$pkgver
+  cp -a python python-css
+}
+
+build() {
+  cd js-beautify-$pkgver/python
+  python setup-js.py build
+  cd ../python-css
+  python setup-css.py build
+}
+
+check() {
+  cd js-beautify-$pkgver
+  python python/js-beautify-test.py
+}
+
+package_python-jsbeautifier() {
+  pkgdesc='JavaScript unobfuscator and beautifier'
+  cd js-beautify-$pkgver/python
+  python setup-js.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -D -m644 -t "$pkgdir"/usr/share/licenses/"${pkgname[0]}" ../LICENSE
+}
+
+package_python-cssbeautifier() {
+  pkgdesc='CSS unobfuscator and beautifier'
+  depends+=('python-jsbeautifier')
+  cd js-beautify-$pkgver/python-css
+  python setup-css.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -D -m644 -t "$pkgdir"/usr/share/licenses/"${pkgname[1]}" ../LICENSE
+}