[arch-commits] Commit in python-matrix-nio/repos (2 files)

[Felix Yan]

    Date: Tuesday, November 10, 2020 @ 05:11:54
  Author: felixonmars
Revision: 749356

archrelease: copy trunk to community-staging-any

Added:
  python-matrix-nio/repos/community-staging-any/
  python-matrix-nio/repos/community-staging-any/PKGBUILD
    (from rev 749355, python-matrix-nio/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: python-matrix-nio/repos/community-staging-any/PKGBUILD (from rev 749355, python-matrix-nio/trunk/PKGBUILD)
===================================================================
--- community-staging-any/PKGBUILD	                        (rev 0)
+++ community-staging-any/PKGBUILD	2020-11-10 05:11:54 UTC (rev 749356)
@@ -0,0 +1,39 @@
+# Maintainer: Jonas Witschel <diabonas at archlinux.org>
+pkgname=python-matrix-nio
+pkgver=0.15.2
+_tag=663e99c39668ab6bfe5ed2a861a51f3834fd714c # git rev-parse "$pkgver"
+pkgrel=2
+pkgdesc='Python Matrix client library, designed according to sans I/O principles'
+arch=('any')
+url='https://github.com/poljar/matrix-nio'
+license=('ISC')
+depends=('python' 'python-aiofiles' 'python-aiohttp' 'python-atomicwrites' 'python-cachetools'
+         'python-future' 'python-h11' 'python-h2' 'python-jsonschema' 'python-logbook' 'python-olm'
+         'python-peewee' 'python-pycryptodome' 'python-unpaddedbase64')
+makedepends=('git')
+checkdepends=('python-aioresponses' 'python-faker' 'python-hpack' 'python-hyperframe' 'python-hypothesis'
+              'python-pytest' 'python-pytest-aiohttp' 'python-pytest-benchmark')
+source=("git+$url.git?signed#tag=$_tag")
+sha512sums=('SKIP')
+validpgpkeys=('689A3B5BC6560AB4C99A2A0581314DA807EF4E22') # Damir Jelić (poljar) <poljar at termina.org.uk>
+
+pkgver() {
+	cd "${pkgname#python-}"
+	git describe | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+}
+
+build() {
+	cd "${pkgname#python-}"
+	python setup.py build
+}
+
+check() {
+	cd "${pkgname#python-}"
+	python -m pytest
+}
+
+package() {
+	cd "${pkgname#python-}"
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+	install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}