[arch-commits] Commit in fasm/repos (community-x86_64 community-x86_64/PKGBUILD)

Levente Polyak anthraxx at archlinux.org
Tue Nov 10 21:44:46 UTC 2020


    Date: Tuesday, November 10, 2020 @ 21:44:46
  Author: anthraxx
Revision: 749888

archrelease: copy trunk to community-x86_64

Added:
  fasm/repos/community-x86_64/
  fasm/repos/community-x86_64/PKGBUILD
    (from rev 749887, fasm/trunk/PKGBUILD)

----------+
 PKGBUILD |   58 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)

Copied: fasm/repos/community-x86_64/PKGBUILD (from rev 749887, fasm/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2020-11-10 21:44:46 UTC (rev 749888)
@@ -0,0 +1,58 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Chris Andrews <christophersimonandrews [at] gmail [dot] com>
+# Contributor: FadeMind <fademind at gmail.com>
+# Contributor: Serge Victor <arch at random.re>
+# Contributor: Krzysztof Wloch <wloszekk [at] gmail [dot] com>
+# Contributor: Luke McCarthy <luke at iogopro.co.uk>
+
+pkgname=fasm
+pkgver=1.73.25
+pkgrel=1
+pkgdesc='Fast and efficient self-assembling x86 assembler for DOS, Windows and Linux operating systems'
+url='https://flatassembler.net/'
+arch=('x86_64')
+license=('custom')
+depends_x86_64=('lib32-glibc' 'lib32-gcc-libs')
+source=(https://flatassembler.net/${pkgname}-${pkgver}.tgz)
+sha512sums=('be63f0a3d0758c6abadf6b3e5c94198ab973873448c8d0c824d072bd69c05d0c443e6597f534caafc1cd4644ea1a9401ebb7fc08e573aa901f4b71ee4fd5825b')
+b2sums=('8708203438d988b7f2cb436a0343c1d035fb0ba031c8828ff42d8cd6d9560d115ea072fbbb3e1147fdf4fe5c447eda630e75d4db6369f42c4b6d6e5f7c5402b3')
+
+build() {
+  cd ${pkgname}
+
+  if [ "${CARCH}" == "x86_64" ]; then
+    SRCDIR=Linux/x64
+    ./fasm.x64 source/${SRCDIR}/fasm.asm
+  fi
+  mv source/${SRCDIR}/fasm ./fasm
+
+  # tools
+  local s
+  for s in listing prepsrc symbols; do
+    ./fasm tools/libc/${s}.asm ${s}.o
+    gcc -m32 ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} -o ${s} ${s}.o
+  done
+}
+
+package() {
+  cd ${pkgname}
+
+  install -Dm 755 fasm -t "${pkgdir}/usr/bin"
+  # tools
+  local s
+  for s in listing prepsrc symbols; do
+    install -Dm 755 ${s} "${pkgdir}/usr/bin/fasm-${s}"
+  done
+
+  # docs
+  install -Dm 644 ${pkgname}.txt whatsnew.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 examples/elfexe/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfexe"
+  install -Dm 644 examples/elfexe/dynamic/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfexe/dynamic"
+  install -Dm 644 examples/elfexe/dynamic/*.inc -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfexe/dynamic"
+  install -Dm 644 examples/elfobj/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/elfobj"
+  install -Dm 644 examples/libcdemo/*.asm -t "${pkgdir}/usr/share/doc/${pkgname}/examples/libcdemo"
+  install -Dm 644 examples/libcdemo/*.inc -t "${pkgdir}/usr/share/doc/${pkgname}/examples/libcdemo"
+  install -Dm 644 license.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et:


More information about the arch-commits mailing list