[arch-commits] Commit in haskell-yesod-test/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 11, 2020 @ 17:30:09
  Author: felixonmars
Revision: 751165

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod-test/repos/community-staging-x86_64/
  haskell-yesod-test/repos/community-staging-x86_64/PKGBUILD
    (from rev 751163, haskell-yesod-test/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-yesod-test/repos/community-staging-x86_64/PKGBUILD (from rev 751163, haskell-yesod-test/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2020-11-11 17:30:09 UTC (rev 751165)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=yesod-test
+pkgname=haskell-yesod-test
+pkgver=1.6.10
+pkgrel=90
+pkgdesc="Integration testing for WAI/Yesod Applications"
+url="https://www.yesodweb.com"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hunit' 'haskell-aeson' 'haskell-attoparsec' 'haskell-blaze-builder'
+         'haskell-blaze-html' 'haskell-case-insensitive' 'haskell-conduit'
+         'haskell-cookie' 'haskell-hspec-core' 'haskell-html-conduit' 'haskell-http-types'
+         'haskell-memory' 'haskell-network' 'haskell-pretty-show' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-xml-conduit' 'haskell-xml-types' 'haskell-yesod-core')
+makedepends=('ghc' 'haskell-yesod-form' 'haskell-hspec' 'haskell-unliftio' 'haskell-unliftio-core')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('badbd76b9a345c86f9dcf8b5d6043f173eec60bf6f39bdcb4a60d17d95ad693991a1c7b4061a1e86d61fb9efe3f2f29b3129e6b9ffef4b07d5b563116959b016')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    sed -i '/semigroups/d' $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}